JavaBhaiLang/install.bat at main · JourneyCodesAyush/JavaBhaiLang · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
@REM BhaiLang installer script .bat file for CMD

@echo off

:: Check for java
where java >nul 2>&1
if %errorlevel% neq 0 (
    echo Java not found
    exit /b 1
)

:: Check for javac
where javac >nul 2>&1
if %errorlevel% neq 0 (
    echo Javac not found
    exit /b 1
)

:: Check for jbang
where jbang >nul 2>&1
if %errorlevel% neq 0 (
    echo Jbang not found
    exit /b 1
)

if "%1" == "" goto help
if "%1" == "--help" goto help
if "%1" == "--install" goto install
if "%1" == "--onetime" goto run_onetime
if "%1" == "--uninstall" goto uninstall
echo Invalid option: %1
goto :eof


:install
echo Installing bhailang globally...
echo jbang alias add --name bhailang https://raw.githubusercontent.com/journeycodesayush/javabhailang/main/bhailang.java

jbang alias add --name bhailang https://raw.githubusercontent.com/journeycodesayush/javabhailang/main/bhailang.java

goto :eof

:run_onetime
echo Running bhailang...
echo jbang https://raw.githubusercontent.com/journeycodesayush/javabhailang/main/bhailang.java
jbang https://raw.githubusercontent.com/journeycodesayush/javabhailang/main/bhailang.java
goto :eof

:uninstall
echo Uninstalling bhailang globally...
echo jbang alias remove bhailang
jbang alias remove bhailang
goto :eof

:help
echo JavaBhaiLang Installer Script
echo =============================
echo.
echo Usage:
echo   script.bat [OPTION]
echo.
echo Options:
echo   --install      Install 'bhailang' globally
echo   --onetime      Run 'bhailang' one time
echo   --uninstall    Remove the global alias
echo   --help         Show this help message
goto :eof