DonationAPI/build.gradle.kts at main · RTUStudio/DonationAPI · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
plugins {
    java
    `maven-publish`
    id("io.freefair.lombok") version "9.2.0"
    id("com.gradleup.shadow") version "9.3.2"
    id("xyz.jpenilla.run-paper") version "3.0.2"
}

val apiVersion = project.property("plugin.api.version") as String
val frameworkVersion = project.property("framework.version") as String

version = project.property("project.version") as String
group = project.property("project.group") as String

tasks.runServer {
    minecraftVersion(project.property("minecraft.version") as String)
    downloadPlugins {
        url("https://ci.codemc.io/job/RTUStudio/job/RSFramework/lastSuccessfulBuild/artifact/builds/plugin/RSFramework-$frameworkVersion.jar")
    }
}

allprojects {
    apply(plugin = "java")
    apply(plugin = "io.freefair.lombok")
    apply(plugin = "com.gradleup.shadow")

    java {
        toolchain.languageVersion.set(JavaLanguageVersion.of(project.property("java.version") as String))
    }

    repositories {
        mavenLocal()
        mavenCentral()
    }

    dependencies {
        // Google/Apache
        compileOnly("com.google.code.gson:gson:2.13.1")
        compileOnly("com.google.guava:guava:33.4.8-jre")
        compileOnly("org.apache.commons:commons-lang3:3.18.0")
        compileOnly("it.unimi.dsi:fastutil:8.5.18")

        // Lombok
        compileOnly("org.projectlombok:lombok:1.18.42")
        annotationProcessor("org.projectlombok:lombok:1.18.42")
        compileOnly("org.slf4j:slf4j-api:2.0.16")
        compileOnly("org.jetbrains:annotations:24.1.0")

        // Web Server
        implementation("io.undertow:undertow-core:2.3.20.Final")
        implementation("org.jboss.xnio:xnio-api:3.8.14.Final")
        implementation("org.jboss.xnio:xnio-nio:3.8.14.Final")

        // Network & Testing
        compileOnly("com.squareup.okhttp3:okhttp:4.12.0")
        testImplementation("org.junit.jupiter:junit-jupiter-api:5.10.0")
        testImplementation("com.squareup.okhttp3:okhttp:4.12.0")
        testImplementation("com.google.code.gson:gson:2.13.1")
        testImplementation("org.slf4j:slf4j-simple:2.0.16")
        testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.10.0")
        testRuntimeOnly("org.junit.platform:junit-platform-launcher")
    }

    tasks.withType<Test> {
        useJUnitPlatform()
    }

    tasks.jar {
        finalizedBy("shadowJar")
    }
}

repositories {
    mavenLocal()
    maven {
        name = "Sonatype"
        url = uri("https://oss.sonatype.org/content/groups/public/")
    }
    maven {
        name = "SpigotMC"
        url = uri("https://hub.spigotmc.org/nexus/content/repositories/snapshots/")
    }
    maven {
        name = "PaperMC"
        url = uri("https://repo.papermc.io/repository/maven-public/")
    }
    maven {
        name = "CodeMC"
        url = uri("https://repo.codemc.io/repository/maven-releases/")
    }
    maven {
        name = "RTUStudio"
        url = uri("https://repo.codemc.io/repository/rtustudio/")
    }
    maven {
        name = "PlaceholderAPI"
        url = uri("https://repo.extendedclip.com/content/repositories/placeholderapi/")
    }
}

dependencies {
    // Platform:Bukkit에 모든 것이 포함됨
    implementation(project(path = ":Platform:Bukkit", configuration = "shadow"))

    implementation(project(path = ":Services:CHZZK", configuration = "shadow"))
    implementation(project(path = ":Services:SOOP", configuration = "shadow"))
    implementation(project(path = ":Services:SSAPI", configuration = "shadow"))
    implementation(project(path = ":Services:CIME", configuration = "shadow"))
    implementation(project(path = ":Services:Toonation", configuration = "shadow"))
    implementation(project(path = ":Services:YouTube", configuration = "shadow"))
}

tasks.shadowJar {
    archiveClassifier.set("")
    archiveBaseName.set(project.name)
}

publishing {
    repositories {
        maven {
            url = uri("https://repo.codemc.io/repository/rtustudio/")

            credentials {
                username = System.getenv("MAVEN_USERNAME")
                password = System.getenv("MAVEN_PASSWORD")
            }
        }
    }

    publications {
        create<MavenPublication>("plugin") {
            groupId = "kr.rtustudio"
            artifactId = "donationapi"
            version = project.version.toString()

            from(components["shadow"])
        }
    }
}