bitcart-docker/justfile at master · bitcart/bitcart-docker · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
set no-exit-message := true

test-args := env("TEST_ARGS", "")

[private]
default:
    @just --list --unsorted --justfile {{ justfile() }}

# services

# run the generator
[group("Services")]
generate:
    @python3 -m generator

# run linters with autofix
[group("Linting")]
lint:
    ruff format . && ruff check --fix .

# run linters (check only)
[group("Linting")]
lint-check:
    ruff format --check . && ruff check .

# run tests
[group("Testing")]
test *args:
    pytest generator/tests/ {{ trim(test-args + " " + args) }}

# run ci checks (without tests)
[group("CI")]
ci-lint: lint-check

# run ci checks
[group("CI")]
ci *args: ci-lint (test args)

# build the demo wheel
[group("Demo")]
build-demo:
    @python3 generator/demo/build.py

# serve the demo
[group("Demo")]
serve-demo: build-demo
    @python3 -m http.server --directory generator/demo -b 127.0.0.1 8080