build: Add packages+devShells+overlays to flake

Author: Waelwindows

flake.nix

@@ -16,12 +16,64 @@
     flake-utils,
     rust-overlay,
   }:
+    let
+      emptyOverlay = final: prev: {};
+      objset-drv = pkgs: pkgs.rustPlatform.buildRustPackage {
+        pname = "objset";
+        version = "v0.1.0";
+
+        src = ./.;
+
+        cargoLock = {
+          # Why I yes, I would like not writing the hash of my Cargo.lock very much.
+          lockFile = ./Cargo.lock;
+        };
+      };
+      objset-python-drv = pkgs: pythonPackages:
+        pythonPackages.buildPythonPackage rec {
+          pname = "objset";
+          version = "v0.1.0";
+
+          src = ./.;
+
+          cargoDeps = pkgs.rustPlatform.importCargoLock {
+            # Why I yes, I would like not writing the hash of my Cargo.lock very much.
+            lockFile = ./Cargo.lock;
+          };
+
+          format = "pyproject";
+
+          # HACK: maturinBuildHook is dumb and doesn't read pyproject.toml for some reason
+          maturinBuildFlags = [ ''--cargo-extra-args="--all-features"'' ];
+
+          nativeBuildInputs = with pkgs.rustPlatform; [ cargoSetupHook maturinBuildHook ];
+
+          # needed for maturin
+          propagatedBuildInputs = with pkgs.python3Packages; [ cffi ];
+      };
+      pythonOverride = prev: (prevArgs: {
+              packageOverrides =
+                let
+                  ourOverlay = new: old: {
+                    objset = objset-python-drv prev old;
+                  };
+                in
+                prev.lib.composeExtensions
+                  prevArgs.packageOverrides or emptyOverlay
+                  ourOverlay;
+            });
+    in
     flake-utils.lib.eachDefaultSystem (
       system: let
         overlays = [(import rust-overlay)];
         pkgs = import nixpkgs {inherit system overlays;};
-      in {
-        devShell = pkgs.mkShell rec {
+      in rec {
+        packages = rec {
+          objset = objset-drv pkgs;
+          objset-python = objset-python-drv pkgs pkgs.python3Packages;
+          default = objset;
+        };
+        devShells.default = pkgs.mkShell rec {
           nativeBuildInputs = with pkgs; [
             (pkgs.rust-bin.nightly.latest.default.override {
               extensions = ["rust-src" "cargo" "rustc"];
@@ -32,12 +84,32 @@
           RUST_SRC_PATH = "${pkgs.rust-bin.nightly.latest.default.override {
             extensions = ["rust-src"];
           }}/lib/rustlib/src/rust/library";
-          buildInputs = with pkgs; [
+          buildNativeInputs = with pkgs; [
             rust-analyzer
             clippy
           ];
-          LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath buildInputs;
+          buildInputs = with pkgs; [
+            maturin
+            (pkgs.python3.withPackages (p: with p; [
+              cffi
+            ]))
+          ];
+          LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath buildNativeInputs;
+        };
+        devShells.python = pkgs.mkShell rec {
+          buildInputs = with pkgs; [
+            (pkgs.python3.withPackages (p: with p; [
+              packages.objset-python
+            ]))
+          ];
         };
       }
-    );
+    ) // {
+    overlays.default = final: prev:
+    rec {
+      objset = objset-drv prev;
+      python310 = prev.python310.override (pythonOverride prev);
+      python39 = prev.python39.override (pythonOverride prev);
+    };
+  };
 }