NetWebView2Lib.au3

#include-once
#AutoIt3Wrapper_Run_AU3Check=Y
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=Y
#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#Au3Stripper_Ignore_Funcs=__NetWebView2_Events__*,__NetWebView2_JSEvents__*

#Tidy_Parameters=/tcb=-1

; NetWebView2Lib.au3 - Script Version: 2.2.1-alpha1 (2026.04.14.10) 🚩

#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <StaticConstants.au3>
#include <StringConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIGdi.au3>
#include <WinAPIShPath.au3>
#include <WinAPISysWin.au3>
#include <WindowsConstants.au3>

#REMARK This UDF is marked as WorkInProgress - you may use them, but do not blame me if I do ScriptBreakingChange and as so far do not ask me for description or help till I remove this remark ; mLipok

#Region UDF Header
; ==============================================================================
; UDF ...........: NetWebView2Lib.au3
; Description ...: A powerful bridge that allows AutoIt to use the modern Microsoft Edge WebView2 (Chromium) engine via a C# COM wrapper.
; Author(s) .....: https://www.autoitscript.com/forum/profile/116386-ioa747
; Author(s) .....: https://www.autoitscript.com/forum/profile/10673-mlipok
; Copyright .....:
;                 * Copyright (c) 2026 ioa747, mLipok
;                 * This project is provided "as-is". You are free to use, modify, and distribute it for both personal and commercial projects.
; URL Links .....:
;                 * https://github.com/ioa747/NetWebView2Lib
;                 * https://www.autoitscript.com/forum/topic/213375-webview2autoit-autoit-webview2-component-com-interop
; Thanks to .....:
;                 * Jonathan Bennett (@Jon) and the AutoIt Team
;                 * @Danp2 https://www.autoitscript.com/forum/profile/29736-danp2 - as his https://github.com/Danp2/au3WebDriver UDF largely inspires us in creating this UDF
; AutoIt Version : v3.3.18.0
; Requirement ...:
;                 * DLL/TLB libraries files that are in the bin folder and were passed during the installation
;                 * .NET Framework 4.8 or higher
;                 * Microsoft Edge WebView2 Runtime version 128.0.2739.15 or higher
; ==============================================================================
#EndRegion UDF Header

#INFO JScript related to WebView2 that we can learn from ; https://github.com/MicrosoftEdge/WebView2Browser/tree/main/wvbrowser_ui

#TODO UDF INDEX - anybody - feel free to make it done - just do not hesitate to full fill this part
#TODO FUNCTION HEADERS SUPLEMENTATION & CHECK - anybody - feel free to make it done - just do not hesitate to full fill this part

; Global objects
Global $_g_bNetWebView2_DebugInfo = True
;~ Global $_g_bNetWebView2_DebugDev = False
Global $_g_bNetWebView2_DebugDev = (@Compiled = 1)
Global $_g_bNetWebView2_Sleep = Sleep                  ; Default to calling standard Sleep function

#Region ; === NetWebView2Lib UDF === ENUMS

;~ Global Enum _
;~ 		$NETWEBVIEW2_ERR__INIT_FAILED, _
;~ 		$NETWEBVIEW2_ERR__PROFILE_NOT_READY, _
;~ 		$NETWEBVIEW2_ERR___FAKE_COUNTER

Global Enum _ ; $NETWEBVIEW2_MESSAGE__* are set by mainly by __NetWebView2_Events__OnMessageReceived() but also others
		$NETWEBVIEW2_MESSAGE__NONE, _ ; UDF setting - not related directly to API REFERENCES
		$NETWEBVIEW2_MESSAGE__INIT_FAILED, _
		$NETWEBVIEW2_MESSAGE__PROFILE_NOT_READY, _
		$NETWEBVIEW2_MESSAGE__INIT_READY, _
		$NETWEBVIEW2_MESSAGE__NAV_STARTING, _
		$NETWEBVIEW2_MESSAGE__URL_CHANGED, _
		$NETWEBVIEW2_MESSAGE__HISTORY_CHANGED, _ ; #TODO https://learn.microsoft.com/en-us/microsoft-edge/webview2/get-started/wpf#step-7---navigation-events
		$NETWEBVIEW2_MESSAGE__SOURCE_CHANGED, _ ; #TODO https://learn.microsoft.com/en-us/microsoft-edge/webview2/get-started/wpf#step-7---navigation-events
		$NETWEBVIEW2_MESSAGE__CONTENT_LOADING, _ ; #TODO https://learn.microsoft.com/en-us/microsoft-edge/webview2/get-started/wpf#step-7---navigation-events
		$NETWEBVIEW2_MESSAGE__BASIC_AUTHENTICATION_REQUESTED, _ ; #TODO WHERE THIS SHOULD be Lower/Higher ?
		$NETWEBVIEW2_MESSAGE__FRAME_NAV_STARTING, _
		$NETWEBVIEW2_MESSAGE__FRAME_NAV_COMPLETED, _
		$NETWEBVIEW2_MESSAGE__FRAME_CONTENT_LOADING, _
		$NETWEBVIEW2_MESSAGE__FRAME_DOM_CONTENT_LOADED, _
		$NETWEBVIEW2_MESSAGE__FRAME_WEB_MESSAGE_RECEIVED, _
		$NETWEBVIEW2_MESSAGE__FRAME_HTML_SOURCE, _
		$NETWEBVIEW2_MESSAGE__CRITICAL_ERROR, _
		$NETWEBVIEW2_MESSAGE__DOM_CONTENT_LOADED, _ ; #TODO https://learn.microsoft.com/en-us/microsoft-edge/webview2/concepts/navigation-events
		$NETWEBVIEW2_MESSAGE__NAV_ERROR, _
		$NETWEBVIEW2_MESSAGE__NAV_COMPLETED, _
		$NETWEBVIEW2_MESSAGE__PROCESS_FAILED, _
		$NETWEBVIEW2_MESSAGE__TITLE_CHANGED, _
		$NETWEBVIEW2_MESSAGE__BROWSER_GOT_FOCUS, _
		$NETWEBVIEW2_MESSAGE__BROWSER_LOST_FOCUS, _
		$NETWEBVIEW2_MESSAGE__WINDOW_RESIZED, _
		$NETWEBVIEW2_MESSAGE__ZOOM_CHANGED, _
		$NETWEBVIEW2_MESSAGE__EXTENSION, _
		$NETWEBVIEW2_MESSAGE__EXTENSION_LOADED, _ ; #TODO Question ? when EXTENSION is loaded ? before $NETWEBVIEW2_MESSAGE__INIT_READY ? before $NETWEBVIEW2_MESSAGE__NAV_COMPLETED ?
		$NETWEBVIEW2_MESSAGE__EXTENSION_FAILED, _
		$NETWEBVIEW2_MESSAGE__EXTENSION_REMOVED, _
		$NETWEBVIEW2_MESSAGE__EXTENSION_NOT_FOUND, _
		$NETWEBVIEW2_MESSAGE__REMOVE_EXTENSION_FAILED, _
		$NETWEBVIEW2_MESSAGE__SELECTED_TEXT, _
		$NETWEBVIEW2_MESSAGE__INNER_TEXT, _
		$NETWEBVIEW2_MESSAGE__INNER_TEXT_FAILED, _
		$NETWEBVIEW2_MESSAGE__HTML_SOURCE, _
		$NETWEBVIEW2_MESSAGE__CAPTURE_SUCCESS, _
		$NETWEBVIEW2_MESSAGE__CAPTURE_ERROR, _
		$NETWEBVIEW2_MESSAGE__PRINT_ERROR, _
		$NETWEBVIEW2_MESSAGE__PDF_EXPORT_SUCCESS, _
		$NETWEBVIEW2_MESSAGE__PDF_EXPORT_ERROR, _
		$NETWEBVIEW2_MESSAGE__CDP_RESULT, _
		$NETWEBVIEW2_MESSAGE__CDP_ERROR, _
		$NETWEBVIEW2_MESSAGE__DATA_CLEARED, _
		$NETWEBVIEW2_MESSAGE__COOKIES_B64, _
		$NETWEBVIEW2_MESSAGE__COOKIES_ERROR, _
		$NETWEBVIEW2_MESSAGE__COOKIE_ADD_ERROR, _
		$NETWEBVIEW2_MESSAGE__BLOCKED_AD, _
		$NETWEBVIEW2_MESSAGE__DOWNLOAD_STARTING, _
		$NETWEBVIEW2_MESSAGE__DOWNLOAD_CANCELLED, _ ; <<--( NEW )--<<
		$NETWEBVIEW2_MESSAGE__DOWNLOAD_IN_PROGRESS, _
		$NETWEBVIEW2_MESSAGE__DOWNLOAD_INTERRUPTED, _
		$NETWEBVIEW2_MESSAGE__DOWNLOAD_COMPLETED, _
		$NETWEBVIEW2_MESSAGE__RESPONSE_RECEIVED, _
		$NETWEBVIEW2_MESSAGE__UNKNOWN_MESSAGE, _
		$NETWEBVIEW2_MESSAGE__USER_ABORT, _
		$NETWEBVIEW2_MESSAGE___FAKE_COUNTER

Global Enum _
		$NETWEBVIEW2_EXECUTEJS_MODE0_FIREANDFORGET, _
		$NETWEBVIEW2_EXECUTEJS_MODE1_ASYNC, _
		$NETWEBVIEW2_EXECUTEJS_MODE2_RESULT, _
		$NETWEBVIEW2_ExecuteJS__FAKE_COUNTER

Global Enum _ ; Indicates the type of process that has failed.
		$NETWEBVIEW2_PROCESS_FAILED_KIND_BROWSER_EXITED, _
		$NETWEBVIEW2_PROCESS_FAILED_KIND_RENDER_EXITED, _
		$NETWEBVIEW2_PROCESS_FAILED_KIND_RENDER_UNRESPONSIVE, _
		$NETWEBVIEW2_PROCESS_FAILED_KIND_FRAME_RENDER_EXITED, _
		$NETWEBVIEW2_PROCESS_FAILED_KIND_UTILITY_EXITED, _
		$NETWEBVIEW2_PROCESS_FAILED_KIND_SANDBOX_EXITED, _
		$NETWEBVIEW2_PROCESS_FAILED_KIND_GPU_EXITED

Global Enum _ ; Indicates the reason for the process failure.
		$NETWEBVIEW2_PROCESS_FAILED_REASON_UNEXPECTED, _
		$NETWEBVIEW2_PROCESS_FAILED_REASON_UNRESPONSIVE, _
		$NETWEBVIEW2_PROCESS_FAILED_REASON_TERMINATED, _
		$NETWEBVIEW2_PROCESS_FAILED_REASON_CRASHED, _
		$NETWEBVIEW2_PROCESS_FAILED_REASON_LAUNCH_FAILED, _
		$NETWEBVIEW2_PROCESS_FAILED_REASON_OUT_OF_MEMORY
#EndRegion ; === NetWebView2Lib UDF === ENUMS

#Region ; === NetWebView2Lib UDF === _NetWebView2_* core functions
; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_CreateManager
; Description ...: Create WebView2 object
; Syntax ........: _NetWebView2_CreateManager([$sUserAgent = ""[, $s_fnEventPrefix = ""[, $s_AddBrowserArgs = ""[,
;                  $bVerbose = False]]]])
; Parameters ....: $sUserAgent          - [optional] a string value. Default is "".
;                  $s_fnEventPrefix     - [optional] a string value. Default is "".
;                  $s_AddBrowserArgs    - [optional] a string value. Default is "". Allows passing command-line switches (e.g., --disable-gpu --mute-audio --proxy-server="...") to the Chromium engine.
;                  $bVerbose            - [optional] True/False - Enable/Disable diagnostic logging. Default is False = Disabled.
; Return values .: None
; Author ........: mLipok, ioa747
; Modified ......:
; Remarks .......: $s_AddBrowserArgs must be set before calling _NetWebView2_Initialize().
;                  Multiple arguments must be separated by a SPACE, not a comma (e.g., "--mute-audio --disable-gpu").
; Related .......:
; Link ..........: https://www.chromium.org/developers/how-tos/run-chromium-with-flags
; Link ..........: https://chromium.googlesource.com/chromium/src/+/main/docs/configuration.md#switches
; Link ..........: https://peter.sh/experiments/chromium-command-line-switches/
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_CreateManager($sUserAgent = "", $s_fnEventPrefix = "", $s_AddBrowserArgs = "", $bVerbose = False)
	Local Const $s_Prefix = "[_NetWebView2_CreateManager]: fnEventPrefix:" & $s_fnEventPrefix & " AddBrowserArgs:" & $s_AddBrowserArgs
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	Local $oWebV2M = ObjCreate("NetWebView2Lib.WebView2Manager") ; REGISTERED VERSION
	$RET = $oWebV2M
	If @error Then
		$ERR = @error
		$EXT = @extended
		$MSG = " Manager Creation Error" & " #SLN=" & @ScriptLineNumber
	Else
		; Enable/Disable diagnostic logging
		; When enabled, the console will show entries like:  +++[NetWebView2Lib][HANDLE:0x...][HH:mm:ss.fff] Message
		; Verbose property was added to allow real-time diagnostic logging to the SciTE console (or any stdout listener).
		; The diagnostic logs use a distinctive prefix and include the instance handle for easier filtering in multi-window applications.
		$oWebV2M.Verbose = $bVerbose
;~ 		If $_g_bNetWebView2_DebugDev Then __NetWebView2_ObjName_FlagsValue($oWebV2M) ; FOR DEV TESTING ONLY

		If $sUserAgent Then $oWebV2M.SetUserAgent($sUserAgent)
		If $s_AddBrowserArgs Then $oWebV2M.AdditionalBrowserArguments = $s_AddBrowserArgs

		ObjEvent($oWebV2M, "__NetWebView2_Events__", "IWebViewEvents")
		If $s_fnEventPrefix Then ObjEvent($oWebV2M, $s_fnEventPrefix, "IWebViewEvents")
		$ERR = @error
		$EXT = @extended
	EndIf
	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_CreateManager

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_Initialize
; Description ...:
; Syntax ........: _NetWebView2_Initialize($oWebV2M, $hUserGUI, $s_ProfileDirectory[, $i_Left = 0[, $i_Top = 0[, $i_Width = 0[,
;                  $i_Height = 0[, $b_SetAutoResize = True[, $b_DevToolsEnabled = True[, $i_ZoomFactor = 1.0[,
;                  $s_BackColor = "0x2B2B2B"[, $b_InitConsole = False]]]]]]]]])
; Parameters ....: $oWebV2M             - an object.
;                  $hUserGUI            - a handle to User window in which new WebView Window containng the controler should be placed/added
;                  $s_ProfileDirectory  - a string value.
;                  $i_Left              - [optional] an integer value. Default is 0.
;                  $i_Top               - [optional] an integer value. Default is 0.
;                  $i_Width             - [optional] an integer value. Default is 0.
;                  $i_Height            - [optional] an integer value. Default is 0.
;                  $b_SetAutoResize     - [optional] a boolean value. Default is True.
;                  $b_DevToolsEnabled   - [optional] a boolean value. Default is True. Allow F12 to show Developer Tools in WebView2 component
;                  $i_ZoomFactor        - [optional] an integer value. Default is 1.0.
;                  $s_BackColor         - [optional] a string value. Default is "0x2B2B2B".
;                  $b_InitConsole       - [optional] a boolean value. Default is False.
; Return values .: $RET ; #TODO description
; Author ........: mLipok, ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_Initialize($oWebV2M, $hUserGUI, $s_ProfileDirectory, $i_Left = 0, $i_Top = 0, $i_Width = 0, $i_Height = 0, $b_SetAutoResize = True, $b_DevToolsEnabled = True, $i_ZoomFactor = 1.0, $s_BackColor = "0x2B2B2B", $b_InitConsole = False)
	Local Const $s_Prefix = "[_NetWebView2_Initialize]: GUI:" & $hUserGUI & " ProfileDirectory:" & $s_ProfileDirectory & " LEFT:" & $i_Left & " TOP:" & $i_Top & " WIDTH:" & $i_Width & " HEIGHT:" & $i_Height & " SETAUTORESIZE:" & $b_SetAutoResize & " SetAutoResize:" & $b_DevToolsEnabled & " ZoomFactor:" & $i_ZoomFactor & " BackColor:" & $s_BackColor
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	If Not IsHWnd($hUserGUI) Then
		$ERR = $NETWEBVIEW2_MESSAGE__CRITICAL_ERROR
		$RET = False
		$MSG = " !!! ERROR: $hUserGUI is not a valid HWND pointer" & " #SLN=" & @ScriptLineNumber
	Else

		; ⚠️ Important: Enclose ($hUserGUI) in parentheses to force "Pass-by-Value".
		; This prevents the COM layer from changing the AutoIt variable type from Ptr to Int64.
		$RET = $oWebV2M.Initialize(($hUserGUI), $s_ProfileDirectory, $i_Left, $i_Top, $i_Width, $i_Height)
		If @error Then
			$ERR = @error
			$EXT = @extended
			$MSG = " !!! ERROR: Initialization COM issue" & " #SLN=" & @ScriptLineNumber
		Else
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__NONE) ; preset Message for specific $sKey = "" & $oWebV2M.BrowserWindowHandle
			If $_g_bNetWebView2_DebugDev Then ConsoleWrite("! IFNC: DEV: FailureReportFolderPath = " & $oWebV2M.FailureReportFolderPath & @CRLF)

			#Region ; After Initialization wait for the engine to be ready before navigating
			Local $hTimer = TimerInit()
			Local $iTimeOut_ms = 10000 ; max 10 seconds for initialization
			Local $iMessage
			Do
				__NetWebView2_Sleep(10)
				If @error Then
					$ERR = @error
					$EXT = @extended
					$RET = ""
					$MSG = " !!! ERROR: Sleep aborted" & " #SLN=" & @ScriptLineNumber
					ExitLoop
				Else
					$iMessage = __NetWebView2_LastMessage_onReceived($oWebV2M) ; get last message
					If $iMessage = $NETWEBVIEW2_MESSAGE__INIT_FAILED _
							Or $iMessage = $NETWEBVIEW2_MESSAGE__PROFILE_NOT_READY _
							Or $iMessage = $NETWEBVIEW2_MESSAGE__PROCESS_FAILED _
							Or $iMessage = $NETWEBVIEW2_MESSAGE__CRITICAL_ERROR Then
						$ERR = 1
						$RET = $iMessage
						$MSG = " !!! ERROR: Last Message= " & $iMessage & " #SLN=" & @ScriptLineNumber
						ExitLoop
					Else
						If TimerDiff($hTimer) >= $iTimeOut_ms Then
							$ERR = 2
							$RET = ""
							$MSG = " !!! ERROR: TimeOut happend" & " #SLN=" & @ScriptLineNumber
							ExitLoop
						EndIf
					EndIf
				EndIf
			Until $oWebV2M.IsReady Or $iMessage = $NETWEBVIEW2_MESSAGE__INIT_READY
;~ 	If Not __NetWebView2_WaitForReadyState($oWebV2M, $hTimer, $iTimeOut_ms) Then Return SetError(2, 0, "")
			#EndRegion ; After Initialization wait for the engine to be ready before navigating

			If Not $ERR Then
				; WebView2 Configuration
				$oWebV2M.SetAutoResize($b_SetAutoResize) ; Using SetAutoResize(True) to skip WM_SIZE
				$oWebV2M.AreDevToolsEnabled = $b_DevToolsEnabled ; Allow F12
				$oWebV2M.ZoomFactor = $i_ZoomFactor
				$oWebV2M.BackColor = $s_BackColor

				If $b_InitConsole Then
					$oWebV2M.AddInitializationScript(__Get_Core_Bridge_JS())
				EndIf

				$EXT = $oWebV2M.GetBrowserProcessId()
			EndIf
		EndIf
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_Initialize

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_IsRegisteredCOMObject
; Description ...: Check if all necessary object are registerd
; Syntax ........: _NetWebView2_IsRegisteredCOMObject()
; Parameters ....: None
; Return values..: Success      - True
;                  Failure      - False and sets @error:
;                                     1 - error registering "NetWebView2Lib.WebView2Manager"
;                                     2 - error registering "NetWebView2Lib.WebView2Parser"
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......: __NetWebView2_fake_COMErrFunc
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_IsRegisteredCOMObject()
	Local Const $s_Prefix = "[_NetWebView2_IsRegisteredCOMObject]:"
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_fake_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	ObjCreate("NetWebView2Lib.WebView2Manager")
	If @error Then
		$ERR = 1
		$MSG = " NetWebView2Lib.WebView2Manager Not Registered" & " #SLN=" & @ScriptLineNumber
	Else
		ObjCreate("NetWebView2Lib.WebView2Parser")
		If @error Then
			$ERR = 2
			$MSG = " NetWebView2Lib.WebView2Parser Not Registered" & " #SLN=" & @ScriptLineNumber
		Else
			$RET = True
		EndIf
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET) ; one common endpoint for entire functions
EndFunc   ;==>_NetWebView2_IsRegisteredCOMObject

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_IsAlreadyInstalled
; Description ...: Check if MS WebView2 is installed or not
; Syntax ........: _NetWebView2_IsAlreadyInstalled()
; Parameters ....: None
; Return values .: True or False
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/pl-pl/microsoft-edge/webview2/concepts/distribution?tabs=dotnetcsharp#detect-if-a-webview2-runtime-is-already-installed
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_IsAlreadyInstalled()
	Local Const $s_Prefix = "[_NetWebView2_IsAlreadyInstalled]:"
	Local $ERR = 0, $EXT = 0, $RET = "", $MSG = "" ; predefined endpoint results
	If @AutoItX64 Then
		$RET = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\EdgeUpdate\Clients\{F3017226-FE2A-4295-8BDF-00C3A9A7E4C5}", "pv")
	Else
		$RET = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\EdgeUpdate\Clients\{F3017226-FE2A-4295-8BDF-00C3A9A7E4C5}", "pv")
	EndIf
	If $RET Then
		$EXT = 1
	Else
		$RET = RegRead("HKEY_CURRENT_USER\Software\Microsoft\EdgeUpdate\Clients\{F3017226-FE2A-4295-8BDF-00C3A9A7E4C5}", "pv")
		$EXT = 2
	EndIf

	If $RET = "" Then $ERR = 1
	If @AutoItX64 Then $EXT += 10

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)

#cs The two registry locations to inspect on 64-bit Windows: https://learn.microsoft.com/pl-pl/microsoft-edge/webview2/concepts/distribution?tabs=dotnetcsharp#detect-if-a-webview2-runtime-is-already-installed
HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\EdgeUpdate\Clients\{F3017226-FE2A-4295-8BDF-00C3A9A7E4C5}
HKEY_CURRENT_USER\Software\Microsoft\EdgeUpdate\Clients\{F3017226-FE2A-4295-8BDF-00C3A9A7E4C5}
#ce The two registry locations to inspect on 64-bit Windows: https://learn.microsoft.com/pl-pl/microsoft-edge/webview2/concepts/distribution?tabs=dotnetcsharp#detect-if-a-webview2-runtime-is-already-installed

#cs The two registry locations to inspect on 32-bit Windows: https://learn.microsoft.com/pl-pl/microsoft-edge/webview2/concepts/distribution?tabs=dotnetcsharp#detect-if-a-webview2-runtime-is-already-installed
HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\EdgeUpdate\Clients\{F3017226-FE2A-4295-8BDF-00C3A9A7E4C5}
HKEY_CURRENT_USER\Software\Microsoft\EdgeUpdate\Clients\{F3017226-FE2A-4295-8BDF-00C3A9A7E4C5}
#ce The two registry locations to inspect on 32-bit Windows: https://learn.microsoft.com/pl-pl/microsoft-edge/webview2/concepts/distribution?tabs=dotnetcsharp#detect-if-a-webview2-runtime-is-already-installed

EndFunc   ;==>_NetWebView2_IsAlreadyInstalled

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_CleanUp
; Description ...:
; Syntax ........: _NetWebView2_CleanUp(ByRef $oWebV2M, ByRef $oJSBridge)
; Parameters ....: $oWebV2M             - [in/out] an object.
;                  $oJSBridge           - [in/out] an object.
; Return values .: None
; Author ........: mLipok, ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_CleanUp(ByRef $oWebV2M, ByRef $oJSBridge)
	Local Const $s_Prefix = "[_NetWebView2_CleanUp]:"
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	If Not IsObj($oWebV2M) Then
		$ERR = 1
		$EXT = 1
		$MSG = " ! NetWebView2Lib.WebView2Manager is not object" & " #SLN=" & @ScriptLineNumber
	ElseIf ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then
		$ERR = 2
		$EXT = 1
		$MSG = " ! NetWebView2Lib.WebView2Manager object has invalid ProgID=" & ObjName($oWebV2M, $OBJ_PROGID) & " #SLN=" & @ScriptLineNumber
;~ 	ElseIf Not IsObj($oJSBridge) Then ; $oJSBridge usage is optional
;~ 		$ERR = 3
;~ 		$EXT = 2
;~ 		$MSG = " ! NetWebView2Lib.WebView2Bridge is not object" & " #SLN=" & @ScriptLineNumber
	ElseIf IsObj($oJSBridge) And ObjName($oJSBridge, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Bridge" Then ; $oJSBridge usage is optional
		$ERR = 4
		$EXT = 2
		$MSG = " ! NebView2Lib.WebView2Bridge object has invalid ProgID=" & ObjName($oJSBridge, $OBJ_PROGID) & " #SLN=" & @ScriptLineNumber
	Else
		_NetWebView2_SetLockState($oWebV2M, True)
		Local $sKey = "" & $oWebV2M.BrowserWindowHandle
		$RET = $oWebV2M.Cleanup()
		$ERR = @error
		If $ERR Then $MSG = " ! Error during internal CleanUp" & " #SLN=" & @ScriptLineNumber

		$oWebV2M = 0
		$oJSBridge = 0

		; Update Static Map to delete Handle
		__NetWebView2_LastMessage_KEEPER($sKey, -1)
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_CleanUp

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_ExecuteScript
; Description ...:
; Syntax ........: _NetWebView2_ExecuteScript($oWebV2M, $sJavaScript[, $iMode = 0])
; Parameters ....: $oWebV2M             - an object.
;                  $sJavaScript         - a string value.
;                  $iMode               - [optional] Default is $NETWEBVIEW2_EXECUTEJS_MODE0_FIREANDFORGET. One of the following search modes:
;                  |0 - $NETWEBVIEW2_EXECUTEJS_MODE0_FIREANDFORGET - Execute, do not wait "Fire-and-Forget"
;                  |1 - $NETWEBVIEW2_EXECUTEJS_MODE1_ASYNC - ExecuteScriptOnPage "Async-Void Trap"
;                  |2 - $NETWEBVIEW2_EXECUTEJS_MODE2_RESULT - ExecuteScriptWithResult - This is the only method designed to return data
; Return values .: None
; Author ........: mLipok, ioa747
; Modified ......:
; Remarks .......: $iMode additionall information:
; 					$NETWEBVIEW2_EXECUTEJS_MODE0_FIREANDFORGET - ExecuteScript (Fire-and-Forget)
; 						In the C# bridge, this is defined as a public void. It uses _webView.Invoke to send the command to the UI thread and exits immediately. It does not wait for the JavaScript to execute, and it has no return type.
; 						Use case: Clicking buttons, scrolling, or triggering JS events where you don't care about the result.
; 					$NETWEBVIEW2_EXECUTEJS_MODE1_ASYNC - ExecuteScriptOnPage (Async-Void Trap)
; 						This is defined as public async void. In COM Interop (which AutoIt uses), an async void method returns control to the caller (AutoIt) the moment it hits the first internal await. The script runs in the background, but the result is never passed back to the COM interface.
; 						Use case: Fast execution where background processing is acceptable, but again, no return value.
; 					$NETWEBVIEW2_EXECUTEJS_MODE2_RESULT - ExecuteScriptWithResult
; 						This is the only method designed to return data. It implements a Message Pump (using Application.DoEvents()) to keep the interface responsive while waiting up to 5 seconds for the result.
; 						Key Features of ExecuteScriptWithResult:
; 						Blocking: It waits for the script to finish (Sync-like behavior for AutoIt).
; 						JSON Cleaning: WebView2 returns results as JSON strings (e.g., "Hello"). This method automatically strips the extra quotes and unescapes the string for you.
; 						Error Handling: Returns ERROR: Script Timeout if the JS takes longer than 5 seconds.
; Related .......:
; Link ..........: https://github.com/ioa747/NetWebView2Lib/issues/45#issuecomment-3831184514
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_ExecuteScript($oWebV2M, $sJavaScript, $iMode = $NETWEBVIEW2_EXECUTEJS_MODE0_FIREANDFORGET)
	Local Const $s_Prefix = "[_NetWebView2_ExecuteScript]:" & " TYPE:" & $iMode
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	Switch $iMode
		Case 0
			$RET = $oWebV2M.ExecuteScript($sJavaScript)
			$ERR = @error
			If @error Then $MSG = " ! Manager.ExecuteScript($sJavaScript) ERROR" & " #SLN=" & @ScriptLineNumber
		Case 1
			$RET = $oWebV2M.ExecuteScriptOnPage($sJavaScript)
			$ERR = @error
			If @error Then $MSG = " ! Manager.ExecuteScriptOnPage($sJavaScript) ERROR" & " #SLN=" & @ScriptLineNumber
		Case 2
			$RET = $oWebV2M.ExecuteScriptWithResult($sJavaScript)
			$ERR = @error
			If @error Then $MSG = " ! Manager.ExecuteScriptWithResult($sJavaScript) ERROR" & " #SLN=" & @ScriptLineNumber
	EndSwitch
	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_ExecuteScript

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_GetBridge
; Description ...:
; Syntax ........: _NetWebView2_GetBridge($oWebV2M[, $s_fnEventPrefix = ""])
; Parameters ....: $oWebV2M             - an object.
;                  $s_fnEventPrefix     - [optional] a string value. Default is "".
; Return values .: None
; Author ........: mLipok, ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_GetBridge($oWebV2M, $s_fnEventPrefix = "")
	Local Const $s_Prefix = "[_NetWebView2_GetBridge]:" & " fnEventPrefix:" & $s_fnEventPrefix
	Local $ERR = 0, $EXT = 0, $RET = 0, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	Local $oWebJS = $oWebV2M.GetBridge()
	If @error Then
		$ERR = @error
		$MSG = " ! Manager.GetBridge() ERROR" & " #SLN=" & @ScriptLineNumber
	Else
		ObjEvent($oWebJS, "__NetWebView2_JSEvents__", "IBridgeEvents")
		If $s_fnEventPrefix Then ObjEvent($oWebJS, $s_fnEventPrefix, "IBridgeEvents")
		$RET = $oWebJS
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_GetBridge

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_GetVersion
; Description ...: Get NetWebView2Lib component version number
; Syntax ........: _NetWebView2_GetVersion($oWebV2M)
; Parameters ....: $oWebV2M             - an object.
; Return values .: NetWebView2Lib component version number or set @error
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_GetVersion($oWebV2M)
	Local Const $s_Prefix = "[_NetWebView2_GetVersion]:"
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	$RET = $oWebV2M.version
	$ERR = @error
	$MSG = " : Version=" & $RET & " #SLN=" & @ScriptLineNumber

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_GetVersion

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_LoadWait
; Description ...: Waits for a specific WebView2 status or event with a timeout.
; Syntax ........: _NetWebView2_LoadWait($oWebV2M[, $iWaitMessage = $NETWEBVIEW2_MESSAGE__TITLE_CHANGED[, $sExpectedTitle = ""[,
;                  $iTimeOut_ms = 5000]]])
; Parameters ....: $oWebV2M             - The NetWebView2 Manager object.
;                  $iWaitMessage        - The status code to wait for (Default is $NETWEBVIEW2_MESSAGE__TITLE_CHANGED).
;                  $sExpectedTitle      - [optional] Expected title to LoadWait for, as StringRegExp() pattern
;                  $iTimeOut_ms         - [optional] Maximum time to wait in milliseconds. 0 for infinite. Default is 5000ms
; Return values .: Success      - True
;                  Failure      - False and sets @error:
#TODO @error numbers changed revise the header
;                                     3 - Navigation Error ($NETWEBVIEW2_MESSAGE__NAV_ERROR)
;                                     4 - Timeout reached
; Author ........: mLipok, ioa747
; Modified ......:
; Remarks .......: This function uses a centralized state machine to track asynchronous events.
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_LoadWait($oWebV2M, $iWaitMessage = $NETWEBVIEW2_MESSAGE__TITLE_CHANGED, $sExpectedTitle = "", $iTimeOut_ms = 5000)
	Local Const $s_Prefix = "[_NetWebView2_LoadWait]: WaitMessage:" & $iWaitMessage & " ExpectedTitle:" & (($sExpectedTitle) ? ($sExpectedTitle) : ("[is EMPTY]")) & " TimeOut_ms:" & $iTimeOut_ms
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $hTimer = TimerInit()

	; RESET: Clear the status of this instance before starting the wait loop
	__NetWebView2_LastMessage_Navigation($oWebV2M, $NETWEBVIEW2_MESSAGE__NONE)

	While 1
		__NetWebView2_Sleep(10) ; Allow AutoIt to "breathe" and process the GUI messages, also allow user to abort
		If @error Then
			$ERR = @error
			$EXT = @extended
			$RET = False
			ExitLoop
		EndIf

		Local $bWebIsReady = $oWebV2M.IsReady ; RULE 1: Check if browser IsReady
		If @error Then ; browser/COM error ?
			$ERR = 1
			$RET = False
			ExitLoop
		ElseIf $iTimeOut_ms And TimerDiff($hTimer) >= $iTimeOut_ms Then ; RULE 2: TimeOut Check
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " - TIME OUT - the waiting time has expired", 1, $ERR, $EXT)
			$ERR = 2
			$RET = False
			ExitLoop
		ElseIf Not $bWebIsReady Then ; RULE 3: if browser is not ready continue waiting
			ContinueLoop ; For navigation events, ensure the browser reports IsReady
		EndIf

		; RULE 4: checking browser DOM ReadyState
		Local $iLastMessage = -1
		Local $sReadyState = _NetWebView2_ExecuteScript($oWebV2M, "document.readyState", $NETWEBVIEW2_EXECUTEJS_MODE2_RESULT)
		If @error Then ; RULE 4: checking ready state - DOM should not fire event
			$ERR = 3
			$RET = False
			$MSG = " document.readyState execution Error" & " #SLN=" & @ScriptLineNumber
			ExitLoop
		ElseIf StringLeft($sReadyState, 6) == "ERROR:" Then ; RULE 4: checking ready state JavaScript result on case of error
			$ERR = 4
			$RET = False
			$MSG = " document.readyState execution Error" & " #SLN=" & @ScriptLineNumber
			ExitLoop
		ElseIf $sReadyState = "complete" Then ; RULE 4: checking browser DOM ReadyState is "complete"
			$iLastMessage = __NetWebView2_LastMessage_Navigation($oWebV2M)
			If $_g_bNetWebView2_DebugDev Then ConsoleWrite("! IFNC: DEV: TEST LOAD WAIT: ReadyState=" & $sReadyState & " LastMessage=" & $iLastMessage & " WaitMessage=" & $iWaitMessage & " #SLN=" & @ScriptLineNumber & @CRLF)
			If $iLastMessage = $NETWEBVIEW2_MESSAGE__NAV_ERROR Or $iLastMessage = $NETWEBVIEW2_MESSAGE__PROCESS_FAILED Or $iLastMessage = $NETWEBVIEW2_MESSAGE__CRITICAL_ERROR Then ; RULE 5: messages of specific Error occurs
				If $_g_bNetWebView2_DebugDev Then ConsoleWrite("! IFNC: DEV: TEST LOAD WAIT:" & $iLastMessage & " #SLN=" & @ScriptLineNumber & @CRLF)
				$ERR = 5
				$RET = False
				ExitLoop
			ElseIf $iLastMessage >= $iWaitMessage Then ; RULE 6: checking requested events messages
				If $iWaitMessage = $NETWEBVIEW2_MESSAGE__TITLE_CHANGED And $sExpectedTitle Then ; RULE 7: checking Expected document title - only if $NETWEBVIEW2_MESSAGE__TITLE_CHANGED was choosed
					Local $sCurrentTitle = $oWebV2M.GetDocumentTitle()
					Local $bTitleCheck = (StringRegExp($sCurrentTitle, $sExpectedTitle, $STR_REGEXPMATCH) = 1)
					Local $s_DEV_Info = "! IFNC: DEV: TEST LOAD WAIT: Prefix:: " & $s_Prefix & " TitleCheck=" & $bTitleCheck & " LastMessage=" & $iLastMessage & " CurrentTitle=" & $sCurrentTitle
					If $_g_bNetWebView2_DebugDev Then ConsoleWrite($s_DEV_Info & " #SLN=" & @ScriptLineNumber & @CRLF)
					If $bTitleCheck Then
						$MSG = " TitleCheck=" & $bTitleCheck & " #SLN=" & @ScriptLineNumber
						$RET = True
						ExitLoop
					EndIf
				Else
					If $_g_bNetWebView2_DebugDev Then ConsoleWrite($s_DEV_Info & " #SLN=" & @ScriptLineNumber & @CRLF)
					$MSG = " LastMessage=" & $iLastMessage & " #SLN=" & @ScriptLineNumber
					$RET = True
					ExitLoop
				EndIf
			EndIf
		EndIf
		If $_g_bNetWebView2_DebugDev Then ConsoleWrite("! IFNC: DEV: TEST LOAD WAIT: __NetWebView2_LastMessage_Navigation($oWebV2M)=" & $iLastMessage & " >> " & __NetWebView2_LastMessage_Navigation($oWebV2M) & " #SLN=" & @ScriptLineNumber & @CRLF)
	WEnd

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_LoadWait

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_Navigate
; Description ...: Navigates to a URL and waits for a specific completion status.
; Syntax ........: _NetWebView2_Navigate($oWebV2M, $s_URL[, $iWaitMessage = $NETWEBVIEW2_MESSAGE__TITLE_CHANGED[,
;                  $sExpectedTitle = ""[, $iTimeOut_ms = 5000]]])
; Parameters ....: $oWebV2M             - The NetWebView2 Manager object.
;                  $s_URL               - The URL to navigate to.
;                  $iWaitMessage        - The status code to wait for (Default is $NETWEBVIEW2_MESSAGE__TITLE_CHANGED).
;                  $sExpectedTitle      - [optional] Expected title to LoadWait for, as StringRegExp() pattern
;                  $iTimeOut_ms         - [optional] Maximum time to wait in milliseconds. 0 for infinite. Default is 5000ms
; Return values .: Success       - True
;                  Failure       - False and sets @error:
;                                      1 - Invalid parameters
;                                      2 - Navigation call failed (COM error)
;                                      3 - Navigation Error status received
;                                      4 - Timeout reached
; Author ........: mLipok, ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_Navigate($oWebV2M, $s_URL, $iWaitMessage = $NETWEBVIEW2_MESSAGE__TITLE_CHANGED, $sExpectedTitle = "", $iTimeOut_ms = 5000)
	Local Const $s_Prefix = "[_NetWebView2_Navigate]: URL:" & $s_URL & " WaitMessage:" & $iWaitMessage & " ExpectedTitle:" & (($sExpectedTitle) ? ($sExpectedTitle) : ("[is EMPTY]")) & " TimeOut_ms:" & $iTimeOut_ms
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	If (Not IsObj($oWebV2M)) Or ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then ; Error 1: Not an object
		$ERR = 1
		$RET = False
		$MSG = " Invalid Object Error" & " #SLN=" & @ScriptLineNumber
	ElseIf $iWaitMessage < $NETWEBVIEW2_MESSAGE__INIT_READY Or $iWaitMessage > $NETWEBVIEW2_MESSAGE__TITLE_CHANGED Then
		; Parameter Validation - higher messsages are not for NAVIGATION thus not checking in _NetWebView2_LoadWait()
		$ERR = 2
		$MSG = " ERROR: $iWaitMessage not valid" & " #SLN=" & @ScriptLineNumber
	Else
		; Execute Navigation
		; The Local Error Handler catches potential "Disposed Object" crashes here
		$oWebV2M.LockWebView()
		$oWebV2M.Navigate($s_URL)
		$ERR = @error
		$EXT = @extended
		If Not @error Then
			; Wait for status using the BulletProof LoadWait logic
			$RET = _NetWebView2_LoadWait($oWebV2M, $iWaitMessage, $sExpectedTitle, $iTimeOut_ms)
			$ERR = @error
			$EXT = @extended
			If @error Then ; If an error occurred (3: Nav Error, 4: Timeout), log the failure
				$MSG = " -> LOAD WAIT FAILED" & " #SLN=" & @ScriptLineNumber
			EndIf
		EndIf
		$oWebV2M.UnLockWebView()
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_Navigate

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_NavigateToString
; Description ...:
; Syntax ........: _NetWebView2_NavigateToString($oWebV2M, $s_HTML[, $iWaitMessage = $NETWEBVIEW2_MESSAGE__TITLE_CHANGED[,
;                  $sExpectedTitle = ""[, $iTimeOut_ms = 5000]]])
; Parameters ....: $oWebV2M             - an object.
;                  $s_HTML              - a string value.
;                  $iWaitMessage        - [optional] an integer value. Default is $NETWEBVIEW2_MESSAGE__TITLE_CHANGED.
;                  $sExpectedTitle      - [optional] Expected title to LoadWait for, as StringRegExp() pattern
;                  $iTimeOut_ms         - [optional] Maximum time to wait in milliseconds. 0 for infinite. Default is 5000ms
; Return values .: None
; Author ........: mLipok, ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_NavigateToString($oWebV2M, $s_HTML, $iWaitMessage = $NETWEBVIEW2_MESSAGE__TITLE_CHANGED, $sExpectedTitle = "", $iTimeOut_ms = 5000)
	Local Const $s_Prefix = "[_NetWebView2_NavigateToString]:" & " HTML Size:" & StringLen($s_HTML) & " WaitMessage:" & $iWaitMessage & " ExpectedTitle:" & (($sExpectedTitle) ? ($sExpectedTitle) : ("[is EMPTY]")) & " TimeOut_ms:" & $iTimeOut_ms
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	If (Not IsObj($oWebV2M)) Or ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then ; Error 1: Not an object
		$ERR = 1
		$RET = False
		$MSG = " Invalid Object Error" & " #SLN=" & @ScriptLineNumber
	ElseIf $iWaitMessage < $NETWEBVIEW2_MESSAGE__INIT_READY Then
		$ERR = 2
		$MSG = " $iWaitMessage Error" & " #SLN=" & @ScriptLineNumber
	ElseIf $iWaitMessage > $NETWEBVIEW2_MESSAGE__TITLE_CHANGED Then ; higher messsages are not for NAVIGATION thus not checking in _NetWebView2_LoadWait()
		$ERR = 3
		$MSG = " $iWaitMessage Error > TITLE_CHANGED" & " #SLN=" & @ScriptLineNumber
	Else
		$oWebV2M.LockWebView()
		$RET = $oWebV2M.NavigateToString($s_HTML)
		$ERR = @error
		If $ERR Then
			$MSG = " NavigateToString Error" & " #SLN=" & @ScriptLineNumber
		Else
			_NetWebView2_LoadWait($oWebV2M, $iWaitMessage, $sExpectedTitle, $iTimeOut_ms)
			$ERR = @error
			$EXT = @extended
			$MSG = " LoadWait internal Error" & " #SLN=" & @ScriptLineNumber
		EndIf
		$oWebV2M.UnLockWebView()
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_NavigateToString

#EndRegion ; === NetWebView2Lib UDF === _NetWebView2_* core functions

#Region ; === NetWebView2Lib UDF === _NetWebView2_* helper functions
; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_BrowserSetupWrapper
; Description ...: Sets up and initializes a browser window using the specified profile and settings.
; Syntax ........: _NetWebView2_BrowserSetupWrapper($hOuterParentWindow, ByRef $oOuterWeb, $sEventPrefix, $sProfile,
;                  ByRef $oOuterBridge, ByRef $hInnerWebViewWindow, $iX, $iY, $iW, $iH, $s_AddBrowserArgs)
; Parameters ....: $hOuterParentWindow  - a handle value.
;                  $oOuterWeb           - [in/out] an object.
;                  $sEventPrefix        - a string value.
;                  $sProfile            - a string value.
;                  $oOuterBridge        - [in/out] an object.
;                  $hInnerWebViewWindow - [in/out] a handle value.
;                  $iX                  - an integer value.
;                  $iY                  - an integer value.
;                  $iW                  - an integer value.
;                  $iH                  - an integer value.
;                  $s_AddBrowserArgs    - a string value.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_BrowserSetupWrapper($hOuterParentWindow, ByRef $oOuterWeb, $sEventPrefix, $sProfile, ByRef $oOuterBridge, ByRef $hInnerWebViewWindow, $iX, $iY, $iW, $iH, $s_AddBrowserArgs)
	Local Const $s_Prefix = "[_NetWebView2_BrowserSetupWrapper]:" & " EventPrefix:" & $sEventPrefix & " Profile:" & $sProfile & " AddBrowserArgs:" & $s_AddBrowserArgs
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	$hInnerWebViewWindow = GUICreate("", $iW, $iH, $iX, $iY, $WS_CHILD, -1, $hOuterParentWindow)
	GUISetState(@SW_SHOW, $hInnerWebViewWindow)

	$oOuterWeb = _NetWebView2_CreateManager("", $sEventPrefix & "_Manager__", $s_AddBrowserArgs)
	If Not @error Then
		_NetWebView2_Initialize($oOuterWeb, $hInnerWebViewWindow, $sProfile, 0, 0, $iW, $iH)
		If Not @error Then
			$oOuterBridge = _NetWebView2_GetBridge($oOuterWeb, $sEventPrefix & "_Bridge__")
			If Not @error Then
				$RET = True
			EndIf
		EndIf
	EndIf
	$ERR = @error
	$EXT = @extended
	$MSG = " InnerWebViewWindow=" & $hInnerWebViewWindow & " BrowserWindowHandle=" & $oOuterWeb.BrowserWindowHandle

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_BrowserSetupWrapper

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_ExportPageData
; Description ...: Captures page data using Chrome DevTools Protocol. Can return MHTML or other CDP formats based on the `cdpParameters` JSON string.
; Syntax ........: _NetWebView2_ExportPageData($oWebV2M, $iFormat[, $sFilePath = ""])
; Parameters ....: $oWebV2M             - an object.
;                  $iFormat             - a string value. 0 HTML only, 1 MHTML Snapshot
;                  $sFilePath           - [optional] a string value. Default is "" which mean make Base64 as a result instead write to file
; Return values .: Success      - Depends on $sFilePath String with Base64 encoded binary content of the PDF or "SUCCESS: File saved to ...."
;                  Failure      - string with error description "ERROR: ........." and set @error to 1
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_ExportPageData($oWebV2M, $iFormat, $sFilePath = "")
	Local Const $s_Prefix = "[_NetWebView2_ExportPageData]:" & " Format:" & $iFormat & " FilePath:" & (($sFilePath) ? ($sFilePath) : ("[is EMPTY]"))
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError
	#TODO $sParameters - search for  => "name": "captureSnapshot" ; https://github.com/ChromeDevTools/devtools-protocol/blob/master/json/browser_protocol.json

	$RET = $oWebV2M.ExportPageData($iFormat, $sFilePath)
	If StringLeft($RET, 6) = "ERROR:" Then
		$ERR = 1
		$MSG = " RESULT:" & $RET & " #SLN=" & @ScriptLineNumber
	Else
		$MSG = " RESULT: SUCCESS" & " #SLN=" & @ScriptLineNumber
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_ExportPageData

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_GetSource
; Description ...: Returns the current URL of the browser.
; Syntax ........: _NetWebView2_GetSource($oWebV2M)
; Parameters ....: $oWebV2M             - an object.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_GetSource($oWebV2M)
	Local Const $s_Prefix = "[_NetWebView2_GetSource]:"
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	$RET = $oWebV2M.GetSource()
	$ERR = @error

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_GetSource

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_NavigateToPDF
; Description ...: Navigate to a PDF (local PDF file or online direct URL link to PDF file)
; Syntax ........: _NetWebView2_NavigateToPDF($oWebV2M, $s_URL_or_FilePath[, $s_Parameters = ""[, $iWaitMessage = $NETWEBVIEW2_MESSAGE__TITLE_CHANGED[,
;                  $sExpectedTitle = ""[, $iTimeOut_ms = 5000[, $iSleepAfter_ms = 1000[, $bFreeze = True]]]]]])
; Parameters ....: $oWebV2M             - an object.
;                  $s_URL_or_FilePath   - a string value.
;                  $s_Parameters        - [optional] a string value. Default is "".
;                  $iWaitMessage        - [optional] an integer value. Default is $NETWEBVIEW2_MESSAGE__TITLE_CHANGED.
;                  $sExpectedTitle      - [optional] Expected title to LoadWait for, as StringRegExp() pattern, By Default vaule it will compute the $s_URL_or_FilePath to guess RegExp for the Title
;                  $iTimeOut_ms         - [optional] Maximum time to wait in milliseconds. 0 for infinite. Default is 5000ms
;                  $iSleepAfter_ms      - [optional] an integer value. Default is 1000.
;                  $bFreeze             - [optional] a boolean value. Default is True.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_NavigateToPDF($oWebV2M, $s_URL_or_FilePath, Const $s_Parameters = "", $iWaitMessage = $NETWEBVIEW2_MESSAGE__TITLE_CHANGED, $sExpectedTitle = Default, $iTimeOut_ms = 5000, Const $iSleepAfter_ms = 1000, Const $bFreeze = True)
	Local Const $s_Prefix = "[_NetWebView2_NavigateToPDF]: URL_or_File:" & $s_URL_or_FilePath & " Parameters:" & $s_Parameters & " WaitMessage:" & $iWaitMessage & " ExpectedTitle:" & (($sExpectedTitle) ? ($sExpectedTitle) : ("[is EMPTY]")) & " TimeOut_ms:" & $iTimeOut_ms & " SleepAfter_ms:" & $iSleepAfter_ms & " Freeze:" & $bFreeze
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results

	If (Not IsObj($oWebV2M)) Or ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then ; Error 1: Not an object
		$ERR = 1
		$RET = False
		$MSG = " Invalid Object Error" & " #SLN=" & @ScriptLineNumber
	Else
		If $sExpectedTitle = Default Then
			Local $aFilePath = StringSplit($s_URL_or_FilePath, "\")
			If @error Then
				$sExpectedTitle = ""
			Else
				$sExpectedTitle = $aFilePath[$aFilePath[0]]
				$sExpectedTitle = StringReplace($sExpectedTitle, "(", "\(")
				$sExpectedTitle = StringReplace($sExpectedTitle, ")", "\)")
				$sExpectedTitle = StringReplace($sExpectedTitle, ".", "\.")
			EndIf
		EndIf

		If FileExists($s_URL_or_FilePath) Then ; check if it is local path - yes=change path - otherwise treat as url
			$s_URL_or_FilePath = StringReplace($s_URL_or_FilePath, "\", "/")
			$s_URL_or_FilePath = StringReplace($s_URL_or_FilePath, " ", "%20")
			$s_URL_or_FilePath = "file:///" & $s_URL_or_FilePath
		EndIf

		If $s_Parameters Then
			$s_URL_or_FilePath &= $s_Parameters
			#TIP: FitToPage: https://stackoverflow.com/questions/78820187/how-to-change-webview2-fit-to-page-button-on-pdf-toolbar-default-to-fit-to-width#comment138971950_78821231
			#TIP: Open desired PAGE: https://stackoverflow.com/questions/68500164/cycle-pdf-pages-in-wpf-webview2#comment135402565_68566860
		EndIf

		Local $idPic = 0
		$oWebV2M.LockWebView()
		If $bFreeze Then __NetWebView2_freezer($oWebV2M, $idPic)
		_NetWebView2_Navigate($oWebV2M, $s_URL_or_FilePath, $iWaitMessage, $sExpectedTitle, $iTimeOut_ms)
		$ERR = @error
		$EXT = @extended
		If Not @error Then __NetWebView2_Sleep($iSleepAfter_ms)

		If $bFreeze And $idPic Then __NetWebView2_freezer($oWebV2M, $idPic)
		$oWebV2M.UnLockWebView()
		$RET = True
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_NavigateToPDF

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_PrintToPdfStream
; Description ...: Print web content to PDF
; Syntax ........: _NetWebView2_PrintToPdfStream($oWebV2M, $b_TBinary_FBase64)
; Parameters ....: $oWebV2M             - an object.
;                  $b_TBinary_FBase64   - a boolean value.
; Return values .: Success      - binary or string with Base64 encoded binary content of the PDF
;                  Failure      - string with error description "ERROR: ........." and set @error to 1
; Author ........: mLipok, ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_PrintToPdfStream($oWebV2M, $b_TBinary_FBase64)
	Local Const $s_Prefix = "[_NetWebView2_PrintToPdfStream]: TBinary_FBase64:" & $b_TBinary_FBase64
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	$RET = $oWebV2M.PrintToPdfStream()
	If StringInStr($RET, "ERROR:") Then
		$ERR = 1
		$MSG = " RESULT:" & $RET & " #SLN=" & @ScriptLineNumber
	Else
		If $b_TBinary_FBase64 Then
			; decode Base64 encoded data do Binary
			$RET = _NetWebView2_DecodeB64ToBinary($oWebV2M, $RET)
			If @error Then $ERR = 2
		EndIf
	EndIf
	If $ERR Then
		$RET = ""
	Else
		$MSG = " RESULT: SUCCESS" & " #SLN=" & @ScriptLineNumber
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_PrintToPdfStream

#EndRegion ; === NetWebView2Lib UDF === _NetWebView2_* helper functions

#Region ; === NetWebView2Lib UDF === New Core Method Wrappers
; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_AddInitializationScript
; Description ...: Adds a JavaScript to be executed before any other script when a new page is loaded.
; Syntax ........: _NetWebView2_AddInitializationScript($oWeb, $sScript)
; Parameters ....: $oWeb    - The NetWebView2 Manager object.
;                  $vScript - The JavaScript code to inject (String) OR the full path to a JavaScript file.
; Return values .: Success  - Returns a Script ID (string).
;                  Failure  - Returns the error message and sets @error.
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......: _NetWebView2_RemoveInitializationScript
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_AddInitializationScript($oWebV2M, $vScript)
	Local Const $s_Prefix = "[_NetWebView2_AddInitializationScript]:"
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	If (Not IsObj($oWebV2M)) Or ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then ; Error 1: Not an object
		$ERR = 1
		$RET = False
		$MSG = " Invalid Object Error" & " #SLN=" & @ScriptLineNumber
	Else
		; Smart Detection
		If FileExists($vScript) Then $vScript = FileRead($vScript)

		$RET = $oWebV2M.AddInitializationScript($vScript) ; Returns a Script ID (string)
		If StringInStr($ERR, "ERROR:") Then $ERR = 2
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_AddInitializationScript

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_RemoveInitializationScript
; Description ...: Removes a previously added initialization script using its ID.
; Syntax ........: _NetWebView2_RemoveInitializationScript($oWebV2M, $sScriptId)
; Parameters ....: $oWebV2M - The Net WebView2 instance to manipulate.
;                  $sScriptId     - The ID of the initialization script to remove.
; Return values .: Success   - True
;                  Failure   - False and sets @error
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......: _NetWebView2_AddInitializationScript
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_RemoveInitializationScript($oWebV2M, $sScriptId)
	Local Const $s_Prefix = "[_NetWebView2_AddInitializationScript]: ScriptId:" & $sScriptId
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	If (Not IsObj($oWebV2M)) Or ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then ; Error 1: Not an object
		$ERR = 1
		$RET = False
		$MSG = " Invalid Object Error" & " #SLN=" & @ScriptLineNumber
	Else
		$oWebV2M.RemoveInitializationScript($sScriptId)
		$ERR = @error
		$RET = (@error = 0)
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_RemoveInitializationScript

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_SetVirtualHostNameToFolderMapping
; Description ...: Maps a custom host name to a local folder path (bypasses CORS).
; Syntax ........: _NetWebView2_SetVirtualHostNameToFolderMapping($oWebV2M, $sHostName, $sFolderPath[, $iAccessKind = 0])
; Parameters ....: $oWebV2M     - The NetWebView2 Manager object.
;                  $sHostName   - The virtual domain (e.g., "myapp.local").
;                  $sFolderPath - The absolute path to the local folder.
;                  $iAccessKind - 0: Allow, 1: Deny, 2: Allow (Cross-Origin restricted).
; Return values .: Success      - True
;                  Failure      - False and sets @error
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_SetVirtualHostNameToFolderMapping($oWebV2M, $sHostName, $sFolderPath, $iAccessKind = 0)
	Local Const $s_Prefix = "[_NetWebView2_SetVirtualHostNameToFolderMapping]: HostName:" & $sHostName & " FolderPath:" & $sFolderPath & " AccessKind:" & $iAccessKind
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	If (Not IsObj($oWebV2M)) Or ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then ; Error 1: Not an object
		$ERR = 1
		$RET = False
		$MSG = " Invalid Object Error" & " #SLN=" & @ScriptLineNumber
	Else
		$oWebV2M.SetVirtualHostNameToFolderMapping($sHostName, $sFolderPath, $iAccessKind)
		$ERR = @error
		$RET = (@error = 0)
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_SetVirtualHostNameToFolderMapping

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_SetLockState
; Description ...: Locks or unlocks the manager to prevent COM calls during critical operations (e.g., Cleanup).
; Syntax ........: _NetWebView2_SetLockState($oWebV2M, $bLockState)
; Parameters ....: $oWebV2M    - The NetWebView2 Manager object.
;                  $bLockState - True to lock (prevent calls), False to unlock.
; Return values .: Success     - True
;                  Failure     - False and sets @error
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_SetLockState($oWebV2M, $bLockState)
	Local Const $s_Prefix = "[_NetWebView2_SetLockState]: LockState:" & $bLockState
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	If (Not IsObj($oWebV2M)) Or ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then ; Error 1: Not an object
		$ERR = 1
		$RET = False
		$MSG = " Invalid Object Error" & " #SLN=" & @ScriptLineNumber
	Else
		$oWebV2M.SetLockState($bLockState)
		$ERR = @error
		$RET = (@error = 0)
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_SetLockState

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_EncodeBinaryToB64
; Description ...: High-performance binary to Base64 string encoding using the C# Core.
; Syntax ........: _NetWebView2_EncodeBinaryToB64($oWebV2M, ByRef $dBinary)
; Parameters ....: $oWebV2M - The NetWebView2 Manager object.
;                  $dBinary - The binary data to encode.
; Return values .: Success  - Returns a Base64 encoded string.
;                  Failure  - Returns an empty string and sets @error.
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......: _NetWebView2_DecodeB64ToBinary
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_EncodeBinaryToB64($oWebV2M, ByRef $dBinary)
	Local Const $s_Prefix = "[_NetWebView2_EncodeBinaryToB64]:"
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	If (Not IsObj($oWebV2M)) Or ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then ; Error 1: Not an object
		$ERR = 1
		$RET = False
		$MSG = " Invalid Object Error" & " #SLN=" & @ScriptLineNumber
	Else
		$RET = $oWebV2M.EncodeBinaryToB64($dBinary)
		If @error Then
			$ERR = @error
			$RET = ""
		EndIf
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_EncodeBinaryToB64

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_DecodeB64ToBinary
; Description ...: High-performance Base64 string to binary data decoding using the C# Core.
; Syntax ........: _NetWebView2_DecodeB64ToBinary($oWebV2M, ByRef $sB64)
; Parameters ....: $oWebV2M - The NetWebView2 Manager object.
;                  $sB64    - The Base64 encoded string to decode.
; Return values .: Success  - Returns binary data.
;                  Failure  - Returns empty binary and sets @error.
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......: _NetWebView2_EncodeBinaryToB64
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_DecodeB64ToBinary($oWebV2M, ByRef $sB64)
	Local Const $s_Prefix = "[_NetWebView2_DecodeB64ToBinary]:"
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results

	If (Not IsObj($oWebV2M)) Or ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then ; Error 1: Not an object
		$ERR = 1
		$EXT = 1
		$RET = Binary("")
		$MSG = " Invalid Object Error" & " #SLN=" & @ScriptLineNumber
	Else
		Local $dResult = $oWebV2M.DecodeB64ToBinary($sB64)
		If @error Then
			$ERR = @error
			$EXT = 2
			$RET = Binary("")
		Else
			$RET = $dResult
		EndIf
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_DecodeB64ToBinary

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_SetBuiltInErrorPageEnabled
; Description ...: Enables or disables the built-in WebView2 error pages (e.g., "No Internet").
; Syntax ........: _NetWebView2_SetBuiltInErrorPageEnabled($oWeb, $bEnabled)
; Parameters ....: $oWeb     - The NetWebView2 Manager object.
;                  $bEnabled - True to show default error pages, False to hide them.
; Return values .: Success   - True
;                  Failure   - False and sets @error
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......: _NetWebView2_EncodeBinaryToB64
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetWebView2_SetBuiltInErrorPageEnabled($oWebV2M, $bEnabled)
	Local Const $s_Prefix = "[_NetWebView2_SetBuiltInErrorPageEnabled]: Enabled:" & $bEnabled
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	If (Not IsObj($oWebV2M)) Or ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then ; Error 1: Not an object
		$ERR = 1
		$RET = False
		$MSG = " Invalid Object Error" & " #SLN=" & @ScriptLineNumber
	Else
		$oWebV2M.IsBuiltInErrorPageEnabled = $bEnabled
		$ERR = @error
		$RET = (@error = 0)
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_SetBuiltInErrorPageEnabled

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetWebView2_GetFrame
; Description ...: Returns a Frame Object (IWebView2Frame) for the specified index.
; Syntax ........: _NetWebView2_GetFrame($oWebV2M, $iIndex)
; Parameters ....: $oWebV2M             - an object.
;                  $iIndex              - an int value.
; Return values .: Success   - Frame Object
;                  Failure   - Null and sets @error
; Author ........: ioa747
; Modified ......: mLipok
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _NetWebView2_GetFrame($oWebV2M, $iIndex)
	Local Const $s_Prefix = "[_NetWebView2_GetFrame]: Index:" & $iIndex
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	If (Not IsObj($oWebV2M)) Or ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then ; Error 1: Not an object
		$ERR = 1
		$RET = Null
		$MSG = " Invalid Object Error" & " #SLN=" & @ScriptLineNumber
	Else
		$RET = $oWebV2M.GetFrame($iIndex)
		$ERR = @error
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetWebView2_GetFrame

; #FUNCTION# ====================================================================================================================
; Name ..........: _WebView2_FrameGetHtmlSource
; Description ...: Synchronously retrieves the full HTML source of a frame.
; Syntax ........: _WebView2_FrameGetHtmlSource($oFrame)
; Parameters ....: $oFrame - The WebView2Frame object.
; Return values .: Success - Clean HTML string.
;                  Failure - Sets @error and returns empty string.
; Author ........: ioa747
; Modified ......: mLipok
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _WebView2_FrameGetHtmlSource($oFrame)
	Local Const $s_Prefix = "[_WebView2_FrameGetHtmlSource]:"
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	If Not IsObj($oFrame) Then
		$ERR = 1
		$RET = ""
	Else
		; Execute script synchronously
		Local $sRaw = $oFrame.ExecuteScriptWithResult("document.documentElement.outerHTML")

		; Basic validation
		If $sRaw = "null" Or $sRaw = "" Then
			$ERR = 1
			$RET = ""
		ElseIf StringLeft($sRaw, 6) = "ERROR:" Then
			$ERR = 2
			$RET = $sRaw
		Else
			; Pre-process: Strip the mandatory JSON quotes BEFORE unescaping.
			; This prevents the C# Parser from "double-wrapping" the string.
			If StringLeft($sRaw, 1) = '"' And StringRight($sRaw, 1) = '"' Then
				$sRaw = StringMid($sRaw, 2, StringLen($sRaw) - 2)
			EndIf

			; Initialize Parser from the library
			Local $oJson = _NetJson_CreateParser()
			If @error Then
				$ERR = 3
				$RET = ""
			Else
				; Use the Parser's UnescapeString to handle all escapes (\uXXXX, \n, \", etc.)
				$RET = $oJson.UnescapeString($sRaw)
				$ERR = @error
			EndIf
		EndIf
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_WebView2_FrameGetHtmlSource

#EndRegion ; === NetWebView2Lib UDF === New Core Method Wrappers

#Region ; === NetWebView2Lib UDF === _NetJson_* functions
; #FUNCTION# ====================================================================================================================
; Name ..........: _NetJson_CreateParser
; Description ...:
; Syntax ........: _NetJson_CreateParser([$sInitialJson = "{}"])
; Parameters ....: $sInitialJson        - [optional] a string value. Default is "{}".
; Return values .: None
; Author ........: mLipok, ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetJson_CreateParser($sInitialJson = "{}")
	Local Const $s_Prefix = "[_NetJson_CreateParser]:"
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	If $sInitialJson = "" Or $sInitialJson = Default Then $sInitialJson = "{}"
	Local $oParser = ObjCreate("NetWebView2Lib.WebView2Parser") ; REGISTERED VERSION
;~ 	If $_g_bNetWebView2_DebugDev Then __NetWebView2_ObjName_FlagsValue($oParser) ; FOR DEV TESTING ONLY
	If @error Or Not IsObj($oParser) Then
		$ERR = 1
		$RET = 0
	Else
		$oParser.Parse($sInitialJson)
		$ERR = @error
		$RET = $oParser
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetJson_CreateParser

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetJson_DecodeB64
; Description ...:
; Syntax ........: _NetJson_DecodeB64($sData)
; Parameters ....: $sData               - a string value.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetJson_DecodeB64($sData)
	Local Const $s_Prefix = "[_NetJson_DecodeB64]:"
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	Local $oJson = _NetJson_CreateParser()
	If @error Then
		$ERR = @error
		$EXT = @extended
		$RET = $oJson
	Else
		Local $dBinary = $oJson.Decode64($sData)
		If @error Then
			$ERR = @error
			$EXT = @extended
		EndIf
		$RET = $dBinary
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetJson_DecodeB64

; #FUNCTION# ====================================================================================================================
; Name ..........: _NetJson_EncodeB64
; Description ...:
; Syntax ........: _NetJson_EncodeB64($sData)
; Parameters ....: $sData               - a string value.
; Return values .: #TODO
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _NetJson_EncodeB64($sData)
	Local Const $s_Prefix = "[_NetJson_EncodeB64]:"
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	Local $oJson = _NetJson_CreateParser()
	If @error Then
		$ERR = @error
		$EXT = 1
		$RET = $oJson
	Else
		Local $vResult = $oJson.EncodeB64($sData)
		If @error Then
			$ERR = @error
			$EXT = 2
		EndIf
		$RET = $vResult
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>_NetJson_EncodeB64
#EndRegion ; === NetWebView2Lib UDF === _NetJson_* functions

#Region ; === NetWebView2Lib UDF === #INTERNAL_USE_ONLY#
; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Sleep
; Description ...: Pause script execution for designated timeframe.
; Syntax ........: __NetWebView2_Sleep($iPause)
; Parameters ....: $iPause - Amount of time to pause (in milliseconds)
; Return values .: Success - None
;                  Failure - None and sets @error $NETWEBVIEW2_MESSAGE__USER_ABORT
; Author ........: @Danp2, mLipok
; Modified ......:
; Remarks .......: Calls standard Sleep() by default. This can be overridden by setting $_g_bNetWebView2_Sleep so that a user supplied function gets called instead.
;                  User's function can throw error which will lead to $NETWEBVIEW2_MESSAGE__USER_ABORT
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func __NetWebView2_Sleep($iPause)
	$_g_bNetWebView2_Sleep($iPause)
	If @error Then Return SetError($NETWEBVIEW2_MESSAGE__USER_ABORT, @extended)
EndFunc   ;==>__NetWebView2_Sleep

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_WaitForReadyState
; Description ...: Polls the browser until the document.readyState reaches "complete".
; Syntax ........: __NetWebView2_WaitForReadyState($oWebV2M, $hTimer[, $iTimeOut_ms = 5000])
; Parameters ....: $oWebV2M       - The WebView2 Manager object.
;                  $hTimer        - a handle to a caller TimerInit
;                  $iTimeOut_ms   - [optional] Maximum time to wait in milliseconds. 0 for infinite. Default is 5000ms
; Return values .: Success: True
;                  Failure: False, sets @error:
;                      1 - Timeout reached before document was complete.
;                      2 - WebView2 object is not valid or ready.
; Author ........: ioa747, mLipok
; Modified.......:
; Remarks .......: This function uses JavaScript execution to check the internal state of the page.
;                  Useful for tasks like PDF printing where "complete" state is mandatory.
; ===============================================================================================================================
Func __NetWebView2_WaitForReadyState($oWebV2M, $hTimer, $iTimeOut_ms = 5000)
	Local Const $s_Prefix = ">>>[__NetWebView2_WaitForReadyState]: TimeOut_ms:" & $iTimeOut_ms
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results

	If (Not IsObj($oWebV2M)) Or ObjName($oWebV2M, $OBJ_PROGID) <> "NetWebView2Lib.WebView2Manager" Then ; Error 1: Not an object
		$ERR = 1
		$RET = False
		$MSG = " Invalid Object Error" & " #SLN=" & @ScriptLineNumber
	EndIf
	Local $sReadyState = ""

	While 1
		; Execute JS via the Bridge (Mode 2)
		$sReadyState = _NetWebView2_ExecuteScript($oWebV2M, "document.readyState", $NETWEBVIEW2_EXECUTEJS_MODE2_RESULT)
		If @error Then
			$ERR = @error
			$EXT = @extended
			$RET = False
			ExitLoop
		ElseIf $sReadyState == "complete" Then ; Check for the "complete" state
			$RET = True
			$MSG = " SUCCESS: Document is ready. Timeout_ms:" & Round(TimerDiff($hTimer), 0) & " #SLN=" & @ScriptLineNumber
			ExitLoop
		ElseIf StringLeft($sReadyState, 6) == "ERROR:" Then ; Check for C# Bridge internal errors (Timeout/Init)
			$ERR = 3
			$RET = False
			$MSG = " BRIDGE " & $sReadyState & " Timeout_ms:" & Round(TimerDiff($hTimer), 0) & " #SLN=" & @ScriptLineNumber
			ExitLoop
		ElseIf $iTimeOut_ms > 0 And TimerDiff($hTimer) > $iTimeOut_ms Then     ; Check for AutoIt-side Timeout
			$ERR = 1
			$RET = False
			$MSG = " TIMEOUT: Document state is " & $sReadyState & " Timeout_ms:" & Round(TimerDiff($hTimer), 0) & " #SLN=" & @ScriptLineNumber
			ExitLoop
		Else
			__NetWebView2_Sleep(50)
			If @error Then
				$ERR = @error
				$EXT = @extended
				$RET = False
				ExitLoop
			EndIf
		EndIf

	WEnd

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>__NetWebView2_WaitForReadyState

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_LastMessage_KEEPER
; Description ...: Centralized state manager for WebView2 instances using a static map.
; Syntax ........: __NetWebView2_LastMessage_KEEPER($oWebV2M[, $iMessage = Default[, $iError = @error[, $iExtended = @extended]]])
; Parameters ....: $oWebV2M             - The NetWebView2 Manager object.
;                  $iMessage            - [optional] Message to keep (store)
;                  $iError              - [optional] an integer value. Default is @error.
;                  $iExtended           - [optional] an integer value. Default is @extended.
; Author.........: mLipok, ioa747
; Modified ......:
; Remarks........: Uses a Local COM Error Handler to silently handle "Disposed Object" errors during shutdown.
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func __NetWebView2_LastMessage_KEEPER($oWebV2M, $iMessage = Default, $iError = @error, $iExtended = @extended)
	Local Const $s_Prefix = ">>>[__NetWebView2_LastMessage_KEEPER]: Message:" & $iMessage
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	__NetWebView2_LastMessage_onReceived($oWebV2M, $iMessage)
	__NetWebView2_LastMessage_Navigation($oWebV2M, $iMessage)

	$ERR = $iError ; prevent @error changes
	$EXT = $iExtended ; prevent @extended changes

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>__NetWebView2_LastMessage_KEEPER

Func __NetWebView2_LastMessage_onReceived($oWebV2M, $iMessage = Default, $iError = @error, $iExtended = @extended)
	Local Const $s_Prefix = ">>>[__NetWebView2_LastMessage_onReceived]: Message:" & $iMessage
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	; Static Map - The central database of status indexed by Window Handle
	; Local COM Error Handler to trap 0x80020009 (Disposed Object) during closure
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_SilentErrorHandler)
	#forceref $oMyError

	Local Static $mLastMessegReceived[]
	Local $sKey = ""
	If IsObj($oWebV2M) Then
		$sKey = "" & $oWebV2M.BrowserWindowHandle
	ElseIf IsString($oWebV2M) And StringRegExp($oWebV2M, "(?i)\A(\[HANDLE:.*?)(0x[\da-f]+)(.*\])\Z", $STR_REGEXPMATCH) Then ; check if is like [HANDLE:0x0000000000240C00]
		$sKey = "" & $oWebV2M
	EndIf

	$RET = __NetWebView2_LastMessage__INTERNALL($mLastMessegReceived, $sKey, $iMessage)

	$ERR = $iError ; prevent @error changes
	$EXT = $iExtended ; prevent @extended changes

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>__NetWebView2_LastMessage_onReceived

Func __NetWebView2_LastMessage_Navigation($oWebV2M, $iMessage = Default, $iError = @error, $iExtended = @extended)
	Local Const $s_Prefix = ">>>[__NetWebView2_LastMessage_Navigation]: Message:" & $iMessage
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
	; Static Map - The central database of status indexed by Window Handle
	; Local COM Error Handler to trap 0x80020009 (Disposed Object) during closure
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_SilentErrorHandler)
	#forceref $oMyError

	Local Static $mLastNavigationMessage[]
	Local $sKey = ""
	If IsObj($oWebV2M) Then
		$sKey = "" & $oWebV2M.BrowserWindowHandle
	ElseIf IsString($oWebV2M) And StringRegExp($oWebV2M, "(?i)\A(\[HANDLE:.*?)(0x[\da-f]+)(.*\])\Z", $STR_REGEXPMATCH) Then ; check if is like [HANDLE:0x0000000000240C00]
		$sKey = "" & $oWebV2M
	EndIf

	If ($iMessage >= $NETWEBVIEW2_MESSAGE__NAV_STARTING And $iMessage <= $NETWEBVIEW2_MESSAGE__TITLE_CHANGED) Or $iMessage = Default Then
		$RET = __NetWebView2_LastMessage__INTERNALL($mLastNavigationMessage, $sKey, $iMessage)
	EndIf

	$ERR = $iError ; prevent @error changes
	$EXT = $iExtended ; prevent @extended changes

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>__NetWebView2_LastMessage_Navigation

Func __NetWebView2_LastMessage__INTERNALL(ByRef $mStatus, $sKey, $iMessage = Default)
	Local Const $s_Prefix = ">>>[__NetWebView2_LastMessage__INTERNALL]: Key:" & $sKey & " Message:" & $iMessage
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results
;~ 	$sKey = StringRegExpReplace($sKey, "(?i)\A(\[HANDLE:.*?)(0x[\da-f]+)(.*\])\Z", "$2") ; example:    [HANDLE:0x0000000000240C00] >> 0x0000000000240C00
;~ 	$sKey = "hwnd" & StringRegExpReplace($sKey, "(?i)\A(\[HANDLE:.*?0x)([\da-f]+)(.*\])\Z", "$2") ; example:    [HANDLE:0x0000000000240C00] >> 0000000000240C00

	If $sKey = "" And $iMessage = -1 Then ; no HANDLE ? remove all mapped statuses
		Local $aMapKeys = MapKeys($mStatus)
		For $vKey In $aMapKeys
			MapRemove($mStatus, $vKey)
		Next
	ElseIf $sKey = "0" Or $sKey = "" Then ; If the handle is invalid
		$ERR = 1
		$MSG = " Invalid KEY value=" & $sKey  & " #SLN=" & @ScriptLineNumber
	ElseIf ($iMessage = -1 Or $iMessage = Default) And Not MapExists($mStatus, $sKey) Then ; for RESET and GET key must exist
		$ERR = 2
		$MSG = " KEY=" & $sKey & " (BrowserWindowHandle) NOT FOUND" & " #SLN=" & @ScriptLineNumber
	ElseIf $iMessage = -1 Then ; If -1, performs cleanup ; Special case: -1 for memory cleanup when the instance is closed
		MapRemove($mStatus, $sKey)
	ElseIf $iMessage = Default Then ; --- GET MODE (Called from LoadWait) ---
		$RET = $mStatus[$sKey]
	Else ; Update the status for this specific Handle
		$mStatus[$sKey] = $iMessage
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>__NetWebView2_LastMessage__INTERNALL

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Log
; Description ...: Debug Write utility
; Syntax ........: __NetWebView2_Log($s_ScriptLineNumber, $sString[, $iErrorNoLineNo = 1[, $iError = @error[, $iExtended = @extended]]])
; Parameters ....: $s_ScriptLineNumber  - a string value.
;                  $sString             - a string value.
;                  $iErrorNoLineNo      - [optional] an integer value. Default is 1.
;                  $iError              - [optional] an integer value. Default is @error.
;                  $iExtended           - [optional] an integer value. Default is @extended.
; Return values .: None
; Author ........: mLipok, ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func __NetWebView2_Log($s_ScriptLineNumber, $sString, $iErrorNoLineNo = 1, $iError = @error, $iExtended = @extended)
	If Not $_g_bNetWebView2_DebugInfo Then Return SetError($iError, $iExtended, 0)
	If $iErrorNoLineNo = 1 Then
		If $iError Then
			$sString = "! ( NetWebView2Lib UDF : #SLN=" & $s_ScriptLineNumber & ", @error=" & $iError & ", @extended=" & $iExtended & " ) :: " & $sString
		Else
			$sString = "+> ( NetWebView2Lib UDF : #SLN=" & $s_ScriptLineNumber & " ) :: " & $sString
		EndIf
	EndIf
	ConsoleWrite($sString & @CRLF)
	Return SetError($iError, $iExtended)
EndFunc   ;==>__NetWebView2_Log

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_ObjName_FlagsValue
; Description ...:
; Syntax ........: __NetWebView2_ObjName_FlagsValue($oObj)
; Parameters ....: $oObj                - an object.
; Return values .: None
; Author ........: AutoIt HelpFile ObjName Example 2
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func __NetWebView2_ObjName_FlagsValue($oObj)
	Local $sInfo = ""
	$sInfo &= "+>" & @TAB & "ObjName($oObj,1) {The name of the Object} =" & @CRLF & @TAB & ObjName($oObj, $OBJ_NAME) & @CRLF

	; HELPFILE REMARKS: Not all Objects support flags 2 to 7. Always test for @error in these cases.
	$sInfo &= "+>" & @TAB & "ObjName($oObj,2) {Description string of the Object} =" & @CRLF & @TAB & ObjName($oObj, $OBJ_STRING)
	If @error Then $sInfo &= "@error = " & @error
	$sInfo &= @CRLF & @CRLF

	$sInfo &= "+>" & @TAB & "ObjName($oObj,3) {The ProgID of the Object} =" & @CRLF & @TAB & ObjName($oObj, $OBJ_PROGID)
	If @error Then $sInfo &= "@error = " & @error
	$sInfo &= @CRLF & @CRLF

	$sInfo &= "+>" & @TAB & "ObjName($oObj,4) {The file that is associated with the object in the Registry} =" & @CRLF & @TAB & ObjName($oObj, $OBJ_FILE)
	If @error Then $sInfo &= "@error = " & @error
	$sInfo &= @CRLF & @CRLF

	$sInfo &= "+>" & @TAB & "ObjName($oObj,5) {Module name in which the object runs (WIN XP And above). Marshaller for non-inproc objects.} =" & @CRLF & @TAB & ObjName($oObj, $OBJ_MODULE)
	If @error Then $sInfo &= "@error = " & @error
	$sInfo &= @CRLF & @CRLF

	$sInfo &= "+>" & @TAB & "ObjName($oObj,6) {CLSID of the object""s coclass} =" & @CRLF & @TAB & ObjName($oObj, $OBJ_CLSID)
	If @error Then $sInfo &= "@error = " & @error
	$sInfo &= @CRLF & @CRLF

	$sInfo &= "+>" & @TAB & "ObjName($oObj,7) {IID of the object""s interface} =" & @CRLF & @TAB & ObjName($oObj, $OBJ_IID)
	If @error Then $sInfo &= "@error = " & @error
	$sInfo &= @CRLF & @CRLF

	ConsoleWrite($sInfo & @CRLF)
EndFunc   ;==>__NetWebView2_ObjName_FlagsValue

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __Get_Core_Bridge_JS
; Description ...: Get JavaScript for Bridge
; Syntax ........: __Get_Core_Bridge_JS()
; Parameters ....: None
; Return values .: JavaScript for Bridge
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func __Get_Core_Bridge_JS()
	Local $sJS = _
			"/**" & @CRLF & _
			" * NetWebView2Lib Core Bridge" & @CRLF & _
			" * Handles Console Hijacking and Global Error Reporting" & @CRLF & _
			" */" & @CRLF & _
			"" & @CRLF & _
			"(function() {" & @CRLF & _
			"    // 1. Configuration & State" & @CRLF & _
			"    window.NET_BRIDGE_ENABLED = true;" & @CRLF & _
			"" & @CRLF & _
			"    /**" & @CRLF & _
			"     * Centralized message dispatcher to AutoIt" & @CRLF & _
			"     */" & @CRLF & _
			"    const dispatchToAutoIt = (data) => {" & @CRLF & _
			"        try {" & @CRLF & _
			"            if (window.chrome && window.chrome.webview) {" & @CRLF & _
			"                window.chrome.webview.postMessage(JSON.stringify(data));" & @CRLF & _
			"            }" & @CRLF & _
			"        } catch (e) {" & @CRLF & _
			"            // Silent fail if bridge is not fully ready" & @CRLF & _
			"        }" & @CRLF & _
			"    };" & @CRLF & _
			"" & @CRLF & _
			"    /**" & @CRLF & _
			"     * Console Hijacking Logic" & @CRLF & _
			"     */" & @CRLF & _
			"    const originalConsole = {" & @CRLF & _
			"        log: console.log," & @CRLF & _
			"        error: console.error," & @CRLF & _
			"        warn: console.warn," & @CRLF & _
			"        info: console.info" & @CRLF & _
			"    };" & @CRLF & _
			"" & @CRLF & _
			"    const createWrappedConsole = (type) => {" & @CRLF & _
			"        return function() {" & @CRLF & _
			"            // Send to AutoIt" & @CRLF & _
			"            dispatchToAutoIt({" & @CRLF & _
			"                type: ""CONSOLE_LOG""," & @CRLF & _
			"                level: type.toUpperCase()," & @CRLF & _
			"                message: Array.from(arguments).map(arg => " & @CRLF & _
			"                    (typeof arg === 'object') ? JSON.stringify(arg) : String(arg)" & @CRLF & _
			"                ).join(' ')," & @CRLF & _
			"                timestamp: new Date().toISOString()" & @CRLF & _
			"            });" & @CRLF & _
			"            // Keep original browser behavior" & @CRLF & _
			"            originalConsole[type].apply(console, arguments);" & @CRLF & _
			"        };" & @CRLF & _
			"    };" & @CRLF & _
			"" & @CRLF & _
			"    // Replace standard console methods" & @CRLF & _
			"    console.log = createWrappedConsole('log');" & @CRLF & _
			"    console.error = createWrappedConsole('error');" & @CRLF & _
			"    console.warn = createWrappedConsole('warn');" & @CRLF & _
			"    console.info = createWrappedConsole('info');" & @CRLF & _
			"" & @CRLF & _
			"    /**" & @CRLF & _
			"     * 2. Global Runtime Error Handler" & @CRLF & _
			"     */" & @CRLF & _
			"    window.onerror = function(message, source, lineno, colno, error) {" & @CRLF & _
			"        dispatchToAutoIt({" & @CRLF & _
			"            type: ""JS_ERROR""," & @CRLF & _
			"            message: message," & @CRLF & _
			"            source: source," & @CRLF & _
			"            line: lineno," & @CRLF & _
			"            column: colno," & @CRLF & _
			"            stack: error ? error.stack : """"" & @CRLF & _
			"        });" & @CRLF & _
			"        return false; // Let browser handle it as well" & @CRLF & _
			"    };" & @CRLF & _
			"" & @CRLF & _
			"    // Signal that bridge is active" & @CRLF & _
			"    dispatchToAutoIt({ type: ""SYSTEM"", message: ""Core Bridge Injected"" });" & @CRLF & _
			"})();"
	Return $sJS
EndFunc   ;==>__Get_Core_Bridge_JS

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_freezer
; Description ...: freez/unfreeze $oWebV2M
; Syntax ........: __NetWebView2_freezer($oWebV2M, ByRef $idPic)
; Parameters ....: $oWebV2M             - an object.
;                  $idPic               - [in/out] an integer value.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func __NetWebView2_freezer($oWebV2M, ByRef $idPic)
	Local Const $s_Prefix = ">>>[__NetWebView2_freezer]:"
	Local $ERR = 0, $EXT = 0, $RET = False, $MSG = "" ; predefined endpoint results

	Local $hWindow_WebView2 = WinGetHandle($oWebV2M.BrowserWindowHandle)

	If $idPic Then ; if $idPic is given then it means you already have it and want to delete it - unfreeze - show WebView2 content
		WinSetState($hWindow_WebView2, "", @SW_SHOW)
		GUICtrlDelete($idPic)
		$RET = 0
	Else
		#Region ; freeze $hWindow_WebView2

		#Region ; add PIC to parent window
		Local $hWindow_Parent = WinGetHandle($oWebV2M.ParentWindowHandle)
		Local $aPos = WinGetPos($hWindow_WebView2)
		Local $hPrev = GUISwitch($hWindow_Parent)
		$idPic = GUICtrlCreatePic("", 0, 0, $aPos[2], $aPos[3])
		Local $hPic = GUICtrlGetHandle($idPic)
		GUISwitch($hPrev)
		#EndRegion ; add PIC to parent window

		Local $hPictureDC = _WinAPI_GetDC($hPic)

		; Create Dest bitmap
		Local $hDestination_DC = _WinAPI_CreateCompatibleDC($hPictureDC) ; Creates a memory device context compatible with the specified device
		Local $hDestination_Bitmap = _WinAPI_CreateCompatibleBitmap($hPictureDC, $aPos[2], $aPos[3]) ; Creates a bitmap compatible with the specified device context
		Local $hDestination_Sv = _WinAPI_SelectObject($hDestination_DC, $hDestination_Bitmap) ; Selects an object into the specified device context

		Local Const $PW_RENDERFULLCONTENT = 0x2 ; this will go to where it should  =)
		_WinAPI_PrintWindow($hWindow_WebView2, $hDestination_DC, $PW_RENDERFULLCONTENT) ; print window to destination Window DC ; https://www.autoitscript.com/forum/topic/153782-help-filedocumentation-issues-discussion-only/page/40/#findComment-1549380

		_WinAPI_ReleaseDC($hPic, $hPictureDC)
		_WinAPI_SelectObject($hDestination_DC, $hDestination_Sv)
		_WinAPI_DeleteDC($hDestination_DC)

		; Set bitmap to control
		_SendMessage($hPic, $STM_SETIMAGE, 0, $hDestination_Bitmap)
		_WinAPI_DeleteObject($hDestination_Bitmap)

		WinSetState($hWindow_WebView2, "", @SW_HIDE)
		$RET = $idPic
		#EndRegion ; freeze $hWindow_WebView2
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & $MSG, 1, $ERR, $EXT)
	Return SetError($ERR, $EXT, $RET)
EndFunc   ;==>__NetWebView2_freezer

#EndRegion ; === NetWebView2Lib UDF === #INTERNAL_USE_ONLY#

#Region ; === NetWebView2Lib UDF === EVENT HANDLERS ***** Collection *****

#Region ; === NetWebView2Lib UDF === EVENT HANDLERS === Error Handlers ===
; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_SilentErrorHandler
; Description ...: A generic COM Error Handler that silences errors.
; Syntax ........: __NetWebView2_SilentErrorHandler()
; Remarks........: Used to prevent script crashes when a WebView2 object is disposed or closed
;                  while an event or a method call is still in progress.
; Author ........: ioa747, mLipok
; ===============================================================================================================================
Volatile Func __NetWebView2_SilentErrorHandler($oError)
	#forceref $oError
	; We do nothing, effectively "swallowing" the COM error.
	; This prevents the "Object Disposed" fatal crash.
	$oError = 0 ; Explicitly release the COM reference inside the volatile scopeEndFunc
EndFunc   ;==>__NetWebView2_SilentErrorHandler

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_COMErrFunc
; Description ...:
; Syntax ........: __NetWebView2_COMErrFunc($oError)
; Parameters ....: $oError              - an object.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_COMErrFunc($oError) ; COM Error Function used by COM Error Handler
	If @Compiled Then Return
	Local $s_INFO = _
			"COM Error intercepted !" & @CRLF & _
			@TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
			@TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
			@TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
			@TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
			@TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
			@TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
			@TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
			@TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
			@TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF
	__NetWebView2_Log($oError.scriptline, $s_INFO, 1)
	$oError = 0 ; Explicitly release the COM reference inside the volatile scopeEndFunc
EndFunc   ;==>__NetWebView2_COMErrFunc

Volatile Func __NetWebView2_fake_COMErrFunc($oError) ; COM Error Function used by COM Error Handler
	#forceref $oError
	; this is only to silently handle _NetWebView2_IsRegisteredCOMObject()
	$oError = 0 ; Explicitly release the COM reference inside the volatile scopeEndFunc
EndFunc   ;==>__NetWebView2_fake_COMErrFunc
#EndRegion ; === NetWebView2Lib UDF === EVENT HANDLERS === Error Handlers ===

#Region ; === NetWebView2Lib UDF === EVENT HANDLERS === MessageReceived ===
; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnMessageReceived
; Description ...: Handles native WebView2 events
; Syntax ........: __NetWebView2_Events__OnMessageReceived($oWebV2M, $hGUI, $sMsg)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $sMsg                - a string value.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2.webmessagereceived?view=webview2-dotnet-1.0.3650.58
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnMessageReceived($oWebV2M, $hGUI, $sMsg)
	Local Const $s_Prefix = ">>>[EVENT: OnMessageReceived]: GUI:" & $hGUI

	#Region ; Message parsing
;~ 	https://github.com/ioa747/NetWebView2Lib/pull/85#issuecomment-3890305808
;~ 	Local $bWasError = False
;~ 	#forceref $bWasError ; 2026/02/12 do not know where or ho to use it
;~ 	If StringLeft($sMsg, 6) = "ERROR|" Then
;~ 		$bWasError = True
;~ 		$sMsg = StringTrimLeft($sMsg, 6)
;~ 	EndIf
	Local $iSplitPos = StringInStr($sMsg, "|")
	Local $sCommand = $iSplitPos ? StringStripWS(StringLeft($sMsg, $iSplitPos - 1), 3) : $sMsg
	Local $sData = $iSplitPos ? StringTrimLeft($sMsg, $iSplitPos) : ""
	Local $aParts

	Local Static $sCommand_static = ""
	If $_g_bNetWebView2_DebugDev And $sCommand_static <> $sCommand Then ; show the log - for DEV only
;~ 		ConsoleWrite("! IFNC: " & $s_Prefix & " #SLN=" & @ScriptLineNumber & " " & $sCommand & " Data=" & (StringLen($sData) > 120 ? StringLeft($sData, 120) & "..." : $sData) & @CRLF) ; FOR DEV TESTING ONLY
		$sCommand_static = $sCommand
	EndIf
	#EndRegion ; Message parsing

	Switch $sCommand
		Case "WINDOW_RESIZED"
			Local Static $sData_static = Null
			If $sData_static <> $sData Then
				$sData_static = $sData
				$aParts = StringSplit($sData, "|")

				If $aParts[0] >= 2 Then
					Local $iW = Int($aParts[1]), $iH = Int($aParts[2])
					; Filter minor resize glitches
					If $iW > 50 And $iH > 50 Then __NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand & ":" & $iW & "x" & $iH, 1)
				EndIf
				__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__WINDOW_RESIZED)
			EndIf

		Case "INIT_FAILED"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__INIT_FAILED)

		Case "INIT_READY"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__INIT_READY)

		Case "WebView2 Profile not ready."
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__PROFILE_NOT_READY)

		Case "NAV_STARTING"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__NAV_STARTING)

		Case "URL_CHANGED"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__URL_CHANGED)

		Case "NAV_ERROR"
			If $sData = "OperationCanceled" Then ; Check if the error is actually a user cancellation
				__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand & " - USER_ABORT Data:" & $sData, 1)
				__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__USER_ABORT)
			Else
				__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand & " Data:" & $sData, 1)
				__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__NAV_ERROR)
				$oWebV2M.Stop() ; We only stop if it is a real error.
			EndIf

			; 🚧 *******************************************
			If $_g_bNetWebView2_DebugDev Then
				ConsoleWrite("! IFNC: DEV: NAV_ERR: " & $sMsg & @CRLF)
				ConsoleWrite("! IFNC: DEV: NAV_ERR: __NetWebView2_LastMessage_onReceived($oWebV2M)=" & __NetWebView2_LastMessage_onReceived($oWebV2M) & " #SLN=" & @ScriptLineNumber & @CRLF)
			EndIf

		Case "NAV_COMPLETED"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__NAV_COMPLETED)

		Case "TITLE_CHANGED"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand & " >> " & $oWebV2M.GetDocumentTitle(), 1)
			#REMARK => __NetWebView2_Events__OnTitleChanged() should set __NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__TITLE_CHANGED)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__TITLE_CHANGED)

		Case "EXTENSION"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__EXTENSION)

		Case "EXTENSION_LOADED"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__EXTENSION_LOADED)

		Case "EXTENSION_FAILED"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__EXTENSION_FAILED)

		Case "EXTENSION_REMOVED"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__EXTENSION_REMOVED)

		Case "EXTENSION_NOT_FOUND"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__EXTENSION_NOT_FOUND)

		Case "REMOVE_EXTENSION_FAILED"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__REMOVE_EXTENSION_FAILED)

		Case "SELECTED_TEXT"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__SELECTED_TEXT)

		Case "INNER_TEXT"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__INNER_TEXT)

		Case "INNER_TEXT_FAILED"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__INNER_TEXT_FAILED)

		Case "HTML_SOURCE"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__HTML_SOURCE)

		Case "CAPTURE_SUCCESS"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__CAPTURE_SUCCESS)

		Case "CAPTURE_ERROR"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__CAPTURE_ERROR)

		Case "PRINT_ERROR"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__PRINT_ERROR)

		Case "PDF_EXPORT_SUCCESS"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__PDF_EXPORT_SUCCESS)

		Case "PDF_EXPORT_ERROR"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__PDF_EXPORT_ERROR)

		Case "CDP_RESULT"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__CDP_RESULT)

		Case "CDP_ERROR"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__CDP_ERROR)

		Case "DATA_CLEARED"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__DATA_CLEARED)

		Case "COOKIES_B64"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__COOKIES_B64)

		Case "COOKIES_ERROR"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__COOKIES_ERROR)

		Case "COOKIE_ADD_ERROR"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__COOKIE_ADD_ERROR)

		Case "BLOCKED_AD"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__BLOCKED_AD)

		Case "DOWNLOAD_STARTING"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__DOWNLOAD_STARTING)

		Case "DOWNLOAD_CANCELLED"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__DOWNLOAD_CANCELLED)	; <<--( NEW )--<<

		Case "BROWSER_GOT_FOCUS"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__BROWSER_GOT_FOCUS)

		Case "BROWSER_LOST_FOCUS"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__BROWSER_LOST_FOCUS)

		Case "FRAME_HTML_SOURCE"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COMMAND:" & $sCommand, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__FRAME_HTML_SOURCE)

		Case "ERROR"
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " ! CRITICAL ERROR:" & $sData, 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__CRITICAL_ERROR)

		Case Else
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " ! UNKNOWN MESSAGE:" & (StringLen($sMsg) > 200 ? StringLeft($sMsg, 200) & "..." : $sMsg), 1)
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__UNKNOWN_MESSAGE)
	EndSwitch

EndFunc   ;==>__NetWebView2_Events__OnMessageReceived

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_JSEvents__OnMessageReceived
; Description ...: Handles custom messages from JavaScript (window.chrome.webview.postMessage)
; Syntax ........: __NetWebView2_JSEvents__OnMessageReceived($oWebV2M, $hGUI, $sMsg)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $sMsg                - a string value.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_JSEvents__OnMessageReceived($oWebV2M, $hGUI, $sMsg)
	#forceref $oWebV2M

	Local Const $s_Prefix = "[JSEvents__OnMessageReceived]: GUI:" & $hGUI
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " MSG=" & (StringLen($sMsg) > 150 ? StringLeft($sMsg, 150) & "..." : $sMsg), 1)
	Local $sFirstChar = StringLeft($sMsg, 1)

	; 1. Modern JSON Messaging
	If $sFirstChar = "{" Or $sFirstChar = "[" Then
		__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " Processing JSON message...", 1)
		Local $oJson = _NetJson_CreateParser()
		If @error Or Not IsObj($oJson) Then
			__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " ERROR: Failed to create NetJson object.", 1)
			Return SetError(@error, @extended, $oJson)
		EndIf

		$oJson.Parse($sMsg)
		Local $sJobType = $oJson.GetTokenValue("type")

		Switch $sJobType
			Case "COM_TEST"
				__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " COM_TEST Confirmed: " & $oJson.GetTokenValue("status"), 1)
		EndSwitch

	Else
		; 2. Legacy / Native Pipe-Delimited Messaging
		__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " Processing Delimited message...", 1)
		Local $sCommand, $sData, $iSplitPos
		$iSplitPos = StringInStr($sMsg, "|") - 1

		If $iSplitPos < 0 Then
			$sCommand = StringStripWS($sMsg, 3)
			$sData = ""
		Else
			$sCommand = StringStripWS(StringLeft($sMsg, $iSplitPos), 3)
			$sData = StringTrimLeft($sMsg, $iSplitPos + 1)
		EndIf

		Switch $sCommand
			Case "ERROR"
				__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " Status General " & $sCommand & ": " & $sData, 1)

			Case "NAV_ERROR"
				__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " Status " & $sCommand & ": " & $sData, 1)

			Case "COM_TEST"
				__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " Status Legacy " & $sCommand & ": " & $sData, 1)

			Case "JSON_CLICKED"
				Local $aClickData = StringSplit($sData, "=", 2) ; Split "Key = Value"
				If UBound($aClickData) >= 2 Then
					Local $sKey = StringStripWS($aClickData[0], 3)
					Local $sVal = StringStripWS($aClickData[1], 3)
					__NetWebView2_Log(@ScriptLineNumber, $s_Prefix & " " & $sCommand & ": Property:" & $sKey & " | Value:" & $sVal, 1)
				EndIf

		EndSwitch
	EndIf

EndFunc   ;==>__NetWebView2_JSEvents__OnMessageReceived
#EndRegion ; === NetWebView2Lib UDF === EVENT HANDLERS === MessageReceived ===

#Region ; === NetWebView2Lib UDF === EVENT HANDLERS === Browser ===
; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnBrowserGotFocus
; Description ...:
; Syntax ........: __NetWebView2_Events__OnBrowserGotFocus($oWebV2M, $hGUI, $iReason)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $iReason             - an integer value.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnBrowserGotFocus($oWebV2M, $hGUI, $iReason)
	Local Const $s_Prefix = ">>>[EVENT: OnBrowserGotFocus]: GUI:" & $hGUI & " REASON:" & $iReason
	__NetWebView2_Log(@ScriptLineNumber, (StringLen($s_Prefix) > 150 ? StringLeft($s_Prefix, 150) & "..." : $s_Prefix), 1)
	__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__BROWSER_GOT_FOCUS)
EndFunc   ;==>__NetWebView2_Events__OnBrowserGotFocus

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnBrowserLostFocus
; Description ...:
; Syntax ........: __NetWebView2_Events__OnBrowserLostFocus($oWebV2M, $hGUI, $iReason)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $iReason             - an integer value.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnBrowserLostFocus($oWebV2M, $hGUI, $iReason)
	Local Const $s_Prefix = ">>>[EVENT: OnBrowserLostFocus]: GUI:" & $hGUI & " REASON:" & $iReason
	__NetWebView2_Log(@ScriptLineNumber, (StringLen($s_Prefix) > 150 ? StringLeft($s_Prefix, 150) & "..." : $s_Prefix), 1)
	__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__BROWSER_LOST_FOCUS)
EndFunc   ;==>__NetWebView2_Events__OnBrowserLostFocus

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnZoomChanged
; Description ...:
; Syntax ........: __NetWebView2_Events__OnZoomChanged($oWebV2M, $hGUI, $iFactor)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $iFactor             - an integer value.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnZoomChanged($oWebV2M, $hGUI, $iFactor)
	Local Const $s_Prefix = ">>>[EVENT: OnZoomChanged]: GUI:" & $hGUI & " FACTOR:" & $iFactor
	__NetWebView2_Log(@ScriptLineNumber, (StringLen($s_Prefix) > 150 ? StringLeft($s_Prefix, 150) & "..." : $s_Prefix), 1)
	__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__ZOOM_CHANGED)
EndFunc   ;==>__NetWebView2_Events__OnZoomChanged

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnURLChanged
; Description ...:
; Syntax ........: __NetWebView2_Events__OnURLChanged($oWebV2M, $hGUI, $sURL)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $sURL                - a string value.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnURLChanged($oWebV2M, $hGUI, $sURL)
	Local Const $s_Prefix = ">>>[EVENT: OnURLChanged]: GUI:" & $hGUI & " URL:" & $sURL
	__NetWebView2_Log(@ScriptLineNumber, (StringLen($s_Prefix) > 150 ? StringLeft($s_Prefix, 150) & "..." : $s_Prefix), 1)
	__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__URL_CHANGED)
EndFunc   ;==>__NetWebView2_Events__OnURLChanged

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnTitleChanged
; Description ...:
; Syntax ........: __NetWebView2_Events__OnTitleChanged($oWebV2M, $hGUI, $sTITLE)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $sTITLE              - a string value.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnTitleChanged($oWebV2M, $hGUI, $sTITLE)
	Local Const $s_Prefix = ">>>[EVENT: OnTitleChanged]: GUI:" & $hGUI & " TITLE:" & $sTITLE
	__NetWebView2_Log(@ScriptLineNumber, (StringLen($s_Prefix) > 150 ? StringLeft($s_Prefix, 150) & "..." : $s_Prefix), 1)
	__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__TITLE_CHANGED)
	If $_g_bNetWebView2_DebugDev Then ConsoleWrite("! IFNC: DEV: TEST LOAD WAIT: __NetWebView2_LastMessage_Navigation($oWebV2M)=" & __NetWebView2_LastMessage_Navigation($oWebV2M) & " #SLN=" & @ScriptLineNumber & @CRLF)
EndFunc   ;==>__NetWebView2_Events__OnTitleChanged

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnNavigationStarting
; Description ...:
; Syntax ........: __NetWebView2_Events__OnNavigationStarting($oWebV2M, $hGUI, $oArgs)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $oArgs               - an object.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2.navigationstarting
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnNavigationStarting($oWebV2M, $hGUI, $oArgs)
	Local $sURL = $oArgs.Uri
	Local Const $s_Prefix = ">>>[EVENT: OnNavigationStarting]: GUI:" & $hGUI & " URL:" & $sURL
	__NetWebView2_Log(@ScriptLineNumber, (StringLen($s_Prefix) > 150 ? StringLeft($s_Prefix, 150) & "..." : $s_Prefix), 1)
	__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__NAV_STARTING)
	$oArgs = 0
EndFunc   ;==>__NetWebView2_Events__OnNavigationStarting

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnNavigationCompleted
; Description ...:
; Syntax ........: __NetWebView2_Events__OnNavigationCompleted($oWebV2M, $hGUI, $bIsSuccess, $iWebErrorStatus)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $bIsSuccess          - a boolean value.
;                  $iWebErrorStatus     - an integer value.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnNavigationCompleted($oWebV2M, $hGUI, $bIsSuccess, $iWebErrorStatus)
	Local Const $s_Prefix = ">>>[EVENT: OnNavigationCompleted]: GUI:" & $hGUI & " " & ($bIsSuccess ? "SUCCESS" : "ERROR ( WebErrorStatus:" & $iWebErrorStatus & ")")
	__NetWebView2_Log(@ScriptLineNumber, (StringLen($s_Prefix) > 150 ? StringLeft($s_Prefix, 150) & "..." : $s_Prefix), 1)
	__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__NAV_COMPLETED)
EndFunc   ;==>__NetWebView2_Events__OnNavigationCompleted

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnContextMenuRequested
; Description ...:
; Syntax ........: __NetWebView2_Events__OnContextMenuRequested($oWebV2M, $hGUI, $sLink, $iX, $iY, $sSelection)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $sLink               - a string value.
;                  $iX                  - an integer value.
;                  $iY                  - an integer value.
;                  $sSelection          - a string value.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnContextMenuRequested($oWebV2M, $hGUI, $sLink, $iX, $iY, $sSelection)
	#forceref $oWebV2M
	Local Const $s_Prefix = ">>>[EVENT: OnContextMenuRequested]: GUI:" & $hGUI & " LINK:" & $sLink & " X:" & $iX & " Y:" & $iY & " SELECTION:" & $sSelection
	__NetWebView2_Log(@ScriptLineNumber, (StringLen($s_Prefix) > 150 ? StringLeft($s_Prefix, 150) & "..." : $s_Prefix), 1)
EndFunc   ;==>__NetWebView2_Events__OnContextMenuRequested

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnContextMenu
; Description ...:
; Syntax ........: __NetWebView2_Events__OnContextMenu($oWebV2M, $hGUI, $sMenuData)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $sMenuData           - a string value.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnContextMenu($oWebV2M, $hGUI, $sMenuData)
	#forceref $oWebV2M
	Local Const $s_Prefix = ">>>[EVENT: OnContextMenu]: GUI:" & $hGUI & " MENUDATA:" & $sMenuData
	__NetWebView2_Log(@ScriptLineNumber, (StringLen($s_Prefix) > 150 ? StringLeft($s_Prefix, 150) & "..." : $s_Prefix), 1)
EndFunc   ;==>__NetWebView2_Events__OnContextMenu

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnWebResourceResponseReceived
; Description ...: Internal handler for the WebResourceResponseReceived event.
; Syntax ........: __NetWebView2_Events__OnWebResourceResponseReceived($oWebV2M, $hGUI, $oArgs)
; Parameters ....: $oWebV2M             - WebView2 object that fired the event
;                  $hGUI                - A handle to Window that fired the event
;                  $oArgs               - An Event Arguments Object containing:
;                                         | .StatusCode (int) [RO]: The HTTP status code (e.g., 200, 404).
;                                         | .ReasonPhrase (string) [RO]: The HTTP reason phrase (e.g., "OK").
;                                         | .RequestUri (string) [RO]: The URL of the request.
;                                         | .IsDocument (bool) [RO]: True if the resource is the main document.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......: 2026-04-14 (Refactored to Object-Oriented Event Model)
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2.webresourceresponsereceived
; Example .......: 007-HTTP_StatusCodeTracking.au3
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnWebResourceResponseReceived($oWebV2M, $hGUI, $oArgs)                                                  ; <<--( NEW )--<<
	Local Const $s_Prefix = ">>>[EVENT: OnWebResourceResponseReceived]: GUI:" & $hGUI & _
	" HTTPStatusCode:" & $oArgs.StatusCode & " (" & $oArgs.ReasonPhrase & ")  URL:" & $oArgs.RequestUri & " URL:" & $oArgs.IsDocument

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
	__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__RESPONSE_RECEIVED)
EndFunc   ;==>__NetWebView2_Events__OnWebResourceResponseReceived

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnDownloadStarting
; Description ...: Internal handler for the DownloadStarting event. Dispatches the event to the user's callback with an Args Object.
; Syntax ........: __NetWebView2_Events__OnDownloadStarting($oWebV2M, $hGUI, $oArgs)
; Parameters ....: $oWebV2M             - The WebView2 Manager object.
;                  $hGUI                - The handle to the GUI window.
;                  $oArgs               - An Event Arguments Object containing:
;                                         | .Uri (String) [RO]: The source URL of the download.
;                                         | .MimeType (String) [RO]: The MIME type (e.g., "application/pdf").
;                                         | .ContentDisposition (String) [RO]: The HTTP Content-Disposition header.
;                                         | .TotalBytesToReceive (Int64) [RO]: Total size in bytes (-1 if unknown).
;                                         | .ResultFilePath (String) [RW]: Get/Set the full target save path.
;                                         | .Cancel (Boolean) [RW]: Set to True to abort the download.
;                                         | .Handled (Boolean) [RW]: Set to True to exit the C# wait loop immediately.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......: 2026-04-14 (Refactored to Object-Oriented Event Model)
; Remarks .......: This event uses a 5000ms synchronization loop in C# to allow for AutoIt interaction (e.g., MsgBox).
; Related .......: _NetWebView2_CreateManager
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2downloadstartingeventargs
; Example .......: 021 - Handle Unviewable Content (MIME).au3
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnDownloadStarting($oWebV2M, $hGUI, $oArgs)                                                                                      ; <<--( NEW )--<<
	Local Const $s_Prefix = "[>>>EVENT: OnDownloadStarting]: GUI:" & $hGUI & " URL: " & $oArgs.Uri & " PATH: " & $oArgs.ResultFilePath & " MIME: " & $oArgs.MimeType
	__NetWebView2_Log(@ScriptLineNumber, (StringLen($s_Prefix) > 150 ? StringLeft($s_Prefix, 150) & "..." : $s_Prefix), 1)
	__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__DOWNLOAD_STARTING)
EndFunc   ;==>__NetWebView2_Events__OnDownloadStarting

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnDownloadStateChanged
; Description ...:
; Syntax ........: __NetWebView2_Events__OnDownloadStateChanged($oWebV2M, $hGUI, $sState, $sURL, $iTotal_Bytes,
;                  $iReceived_Bytes)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $oArgs               - An Event Arguments Object containing:
;                                         | .Uri (String) [RO]: The source URL of the download.
;                                         | .State (String) [RO]: The current state ("InProgress", "Completed", "Interrupted").
;                                         | .TotalBytesToReceive (int) [RO]: Estimated total size.
;                                         | .BytesReceived (int) [RO]: Number of bytes received so far.
;                                         | .PercentComplete (int) [RO]:  Calculation (0-100) or -1 if unknown.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: 006-DownloadDemo.au3
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnDownloadStateChanged($oWebV2M, $hGUI, $oArgs)                                                      ; <<--( NEW )--<<
	Local $iReceived_MB = Round($oArgs.BytesReceived / 1048576, 2) ; 1024*1024
	Local $iTotal_MB = Round($oArgs.TotalBytesToReceive / 1048576, 2)

	Local Const $s_Prefix = "[>>>EVENT: OnDownloadStateChanged]: GUI:" & $hGUI & " State: " & $oArgs.State & " | " & _
	    $oArgs.PercentComplete & "% (" & $iReceived_MB & "/" & $iTotal_MB & " MB) URL: " & $oArgs.Uri

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)

	Switch $oArgs.State
		Case "InProgress"
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__DOWNLOAD_IN_PROGRESS)
		Case "Interrupted"
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__DOWNLOAD_INTERRUPTED)
		Case "Completed"
			__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__DOWNLOAD_COMPLETED)
	EndSwitch
EndFunc

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnAcceleratorKeyPressed
; Description ...: It allows the application to intercept and handle system keys and keyboard shortcuts (Accelerators) before the WebView2 engine processes them.
; Syntax ........: __NetWebView2_Events__OnAcceleratorKeyPressed($oWebV2M, $hGUI, $oArgs)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $oArgs               - An Event Arguments Object containing:
;                                         | .VirtualKey (uint) [RO]: The VK code of the key.
;                                         | .KeyEventKind (int) [RO]: Type of key event (0:KeyDown, 1:KeyUp, etc.).
;                                         | .RepeatCount (uint) [RO]: The number of times the key has repeated.
;                                         | .ScanCode (uint) [RO]: Hardware scan code.
;                                         | .IsExtendedKey (bool) [RO]: True if it's an extended key (e.g., right Alt).
;                                         | .IsMenuKeyDown (bool) [RO]: True if Alt is pressed.
;                                         | .WasKeyDown (bool) [RO]: True if the key was already down.
;                                         | .IsKeyReleased (bool) [RO]: True if the event is a key up.
;                                         | .KeyEventLParam (int) [RO]: The native LPARAM window message value.
;                                         | .Handled (bool) [RW]: Set to True to prevent the browser from executing the default action.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnAcceleratorKeyPressed($oWebV2M, $hGUI, $oArgs)
	#forceref $oWebV2M
	Local Const $sArgsList = _
			"[VirtualKey=" & $oArgs.VirtualKey & _ ; The VK code of the key.
			"; KeyEventKind=" & $oArgs.KeyEventKind & _             ; Type of key event (Down, Up, etc.).
			"; Handled=" & $oArgs.Handled & _                       ; Set to `True` to stop the browser from processing the key.
			"; RepeatCount=" & $oArgs.RepeatCount & _               ; The number of times the key has repeated.
			"; ScanCode=" & $oArgs.ScanCode & _                     ; Hardware scan code.
			"; IsExtendedKey=" & $oArgs.IsExtendedKey & _           ; True if it"s an extended key (e.g., right Alt).
			"; IsMenuKeyDown=" & $oArgs.IsMenuKeyDown & _           ; True if Alt is pressed.
			"; WasKeyDown=" & $oArgs.WasKeyDown & _                 ; True if the key was already down.
			"; IsKeyReleased=" & $oArgs.IsKeyReleased & _           ; True if the event is a key up.
			"; KeyEventLParam=" & $oArgs.KeyEventLParam & "]"       ; Gets the LPARAM value that accompanied the window message.
	Local Const $s_Prefix = ">>>[EVENT: OnAcceleratorKeyPressed]: GUI:" & $hGUI & " $oArgs:" & ((IsObj($oArgs)) ? ($sArgsList) : ("ERROR"))

;~ 	https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2acceleratorkeypressedeventargs?view=webview2-dotnet-1.0.705.50
	If $oArgs.VirtualKey = 27 Then ; ESC 27 1b 033 Escape, next character is not echoed ; https://www.autoitscript.com/autoit3/docs/appendix/ascii.htm
;~ 		$oWebV2M.CancelDownloads($_sURLDownload_InProgress)
	EndIf

	__NetWebView2_Log(@ScriptLineNumber, (StringLen($s_Prefix) > 150 ? StringLeft($s_Prefix, 150) & "..." : $s_Prefix), 1)
	$oArgs = 0 ; Explicitly release the COM reference inside the volatile scopeEndFunc
EndFunc   ;==>__NetWebView2_Events__OnAcceleratorKeyPressed

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnProcessFailed
; Description ...: Fired when a renderer or other browser process fails/crashes.
; Syntax ........: __NetWebView2_Events__OnProcessFailed($oWebV2M, $hGUI, $oArgs)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $oArgs               - an object.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnProcessFailed($oWebV2M, $hGUI, $oArgs)
	Local Const $sArgsList = _
			"[Kind=" & $oArgs.ProcessFailedKind & _
			"; Reason=" & $oArgs.Reason & _
			"; ExitCode=" & $oArgs.ExitCode & _
			"; Description=" & $oArgs.ProcessDescription & "]"
	Local Const $s_Prefix = ">>>[EVENT: OnProcessFailed]: GUI:" & $hGUI & " $oArgs:" & $sArgsList

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
	__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__PROCESS_FAILED)
	$oArgs = 0  ; Explicitly release the COM reference inside the volatile scopeEndFunc
EndFunc   ;==>__NetWebView2_Events__OnProcessFailed

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnBasicAuthenticationRequested
; Description ...: event is raised when WebView encounters a Basic HTTP Authentication request as described in https://developer.mozilla.org/docs/Web/HTTP/Authentication, a Digest HTTP Authentication request as described in https://developer.mozilla.org/docs/Web/HTTP/Headers/Authorization#digest, an NTLM authentication or a Proxy Authentication request.
; Syntax ........: __NetWebView2_Events__OnBasicAuthenticationRequested($oWebV2M, $hGUI, $oArgs)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $oArgs               - an object.
; Return values .: None
; Author ........: ioa747, mLipok
; Modified ......:
; Remarks .......: The host can provide a response with credentials for the authentication or cancel the request.
;                  If the host sets the Cancel property to false but does not provide either UserName or Password properties on the Response property, then WebView2 will show the default authentication challenge dialog prompt to the user.
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2.basicauthenticationrequested
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnBasicAuthenticationRequested($oWebV2M, $hGUI, $oArgs)
	Local Const $sArgsList = _
			"[Uri=" & $oArgs.Uri & _
			"; Challenge=" & $oArgs.Challenge & "]"
	Local Const $s_Prefix = ">>>[EVENT: OnBasicAuthenticationRequested]: GUI:" & $hGUI & " $oArgs:" & $sArgsList

	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
	__NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__BASIC_AUTHENTICATION_REQUESTED)
	; Note: User should handle $oArgs.UserName / $oArgs.Password and call $oArgs.Complete() in their script.
	$oArgs = 0
EndFunc   ;==>__NetWebView2_Events__OnBasicAuthenticationRequested
#EndRegion ; === NetWebView2Lib UDF === EVENT HANDLERS === Browser ===

#Region ; === NetWebView2Lib UDF === EVENT HANDLERS === Frame Related ===
; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnFrameCreated
; Description ...: FrameCreated is raised when a new iframe is created. Handle this event to get access to CoreWebView2Frame objects.
; Syntax ........: __NetWebView2_Events__OnFrameCreated($oWebV2M, $hGUI, $oFrame)
; Parameters ....: $oWebV2M             - an WebV2M object.
;                  $hGUI                - a handle value.
;                  $oFrame              - an Frame object.
; Return values .: None
; Author ........: ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2.framecreated
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnFrameCreated($oWebV2M, $hGUI, $oFrame)
	Local Const $s_Prefix = ">>>[EVENT: OnFrameCreated]: WebV2M:" & VarGetType($oWebV2M) & " GUI:" & $hGUI & " Frame:" & VarGetType($oFrame)
	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
	$oFrame = 0
EndFunc   ;==>__NetWebView2_Events__OnFrameCreated

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnFrameDestroyed
; Description ...: Destroyed event is raised when the iframe corresponding to this CoreWebView2Frame object is removed or the document containing that iframe is destroyed.
; Syntax ........: __NetWebView2_Events__OnFrameDestroyed($oWebV2M, $hGUI, $oFrame)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $oFrame              - an Frame object.
; Return values .: None
; Author ........: ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2frame.destroyed
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnFrameDestroyed($oWebV2M, $hGUI, $oFrame)
	Local Const $s_Prefix = ">>>[EVENT: OnFrameDestroyed]: WebV2M:" & VarGetType($oWebV2M) & " GUI:" & $hGUI & " Frame:" & VarGetType($oFrame)
	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
	$oFrame = 0
EndFunc   ;==>__NetWebView2_Events__OnFrameDestroyed

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnFrameNameChanged
; Description ...: NameChanged is raised when the iframe changes its window.name property.
; Syntax ........: __NetWebView2_Events__OnFrameNameChanged($oWebV2M, $hGUI, $oFrame)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $oFrame              - an Frame object.
; Return values .: None
; Author ........: ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2frame.namechanged
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnFrameNameChanged($oWebV2M, $hGUI, $oFrame)
	Local Const $s_Prefix = ">>>[EVENT: OnFrameNameChanged]: WebV2M:" & VarGetType($oWebV2M) & " GUI:" & $hGUI & " Frame:" & VarGetType($oFrame)
	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
	$oFrame = 0
EndFunc   ;==>__NetWebView2_Events__OnFrameNameChanged

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnFrameNavigationStarting
; Description ...: Handles Frame NavigationStarting event
; Syntax ........: __NetWebView2_Events__OnFrameNavigationStarting($oWebV2M, $hGUI, $oFrame, $oArgs)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $oFrame              - an Frame object.
;                  $oArgs               - an object.
; Return values .: None
; Author ........: ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2frame.navigationstarting
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnFrameNavigationStarting($oWebV2M, $hGUI, $oFrame, $oArgs)
	Local $sUri = $oArgs.Uri
	Local Const $s_Prefix = ">>>[EVENT: OnFrameNavigationStarting]: WebV2M:" & VarGetType($oWebV2M) & " GUI:" & $hGUI & " Frame:" & VarGetType($oFrame) & " Uri:" & $sUri
	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
	; __NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__FRAME_NAV_STARTING) ; Optional: Update status if needed
	$oFrame = 0
EndFunc   ;==>__NetWebView2_Events__OnFrameNavigationStarting

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnFrameNavigationCompleted
; Description ...: Handles Frame NavigationCompleted event
; Syntax ........: __NetWebView2_Events__OnFrameNavigationCompleted($oWebV2M, $hGUI, $oFrame, $bIsSuccess, $iWebErrorStatus)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $oFrame              - an Frame object.
;                  $bIsSuccess          - a boolean value.
;                  $iWebErrorStatus     - an integer value.
; Return values .: None
; Author ........: ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2frame.navigationcompleted
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnFrameNavigationCompleted($oWebV2M, $hGUI, $oFrame, $bIsSuccess, $iWebErrorStatus)
	Local Const $s_Prefix = ">>>[EVENT: OnFrameNavigationCompleted]: WebV2M:" & VarGetType($oWebV2M) & " GUI:" & $hGUI & " Frame:" & VarGetType($oFrame) & " Success:" & $bIsSuccess & " Status:" & $iWebErrorStatus
	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
	; __NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__FRAME_NAV_COMPLETED)
EndFunc   ;==>__NetWebView2_Events__OnFrameNavigationCompleted

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnFrameContentLoading
; Description ...: Handles Frame ContentLoading event
; Syntax ........: __NetWebView2_Events__OnFrameContentLoading($oWebV2M, $hGUI, $oFrame, $iNavigationId)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $oFrame              - an Frame object.
;                  $iNavigationId       - an integer value.
; Return values .: None
; Author ........: ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2frame.contentloading
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnFrameContentLoading($oWebV2M, $hGUI, $oFrame, $iNavigationId)
	Local Const $s_Prefix = ">>>[EVENT: OnFrameContentLoading]: WebV2M:" & VarGetType($oWebV2M) & " GUI:" & $hGUI & " Frame:" & VarGetType($oFrame) & " NavID:" & $iNavigationId
	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
	; __NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__FRAME_CONTENT_LOADING)
	$oFrame = 0
EndFunc   ;==>__NetWebView2_Events__OnFrameContentLoading

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnFrameDOMContentLoaded
; Description ...: Handles Frame DOMContentLoaded event
; Syntax ........: __NetWebView2_Events__OnFrameDOMContentLoaded($oWebV2M, $hGUI, $oFrame, $iNavigationId)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $oFrame              - an Frame object.
;                  $iNavigationId       - an integer value.
; Return values .: None
; Author ........: ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2frame.domcontentloaded
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnFrameDOMContentLoaded($oWebV2M, $hGUI, $oFrame, $iNavigationId)
	Local Const $s_Prefix = ">>>[EVENT: OnFrameDOMContentLoaded]: WebV2M:" & VarGetType($oWebV2M) & " GUI:" & $hGUI & " Frame:" & VarGetType($oFrame) & " NavID:" & $iNavigationId
	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
	; __NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__FRAME_DOM_CONTENT_LOADED)
	$oFrame = 0
EndFunc   ;==>__NetWebView2_Events__OnFrameDOMContentLoaded

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __NetWebView2_Events__OnFrameWebMessageReceived
; Description ...: Handles Frame WebMessageReceived event
; Syntax ........: __NetWebView2_Events__OnFrameWebMessageReceived($oWebV2M, $hGUI, $oFrame, $sMessage)
; Parameters ....: $oWebV2M             - an object.
;                  $hGUI                - a handle value.
;                  $oFrame              - an Frame object.
;                  $sMessage            - a string value.
; Return values .: None
; Author ........: ioa747
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: https://learn.microsoft.com/en-us/dotnet/api/microsoft.web.webview2.core.corewebview2frame.webmessagereceived
; Example .......: No
; ===============================================================================================================================
Volatile Func __NetWebView2_Events__OnFrameWebMessageReceived($oWebV2M, $hGUI, $oFrame, $sMessage)
	Local Const $s_Prefix = ">>>[EVENT: OnFrameWebMessageReceived]: WebV2M:" & VarGetType($oWebV2M) & " GUI:" & $hGUI & " Frame:" & VarGetType($oFrame) & " Message:" & $sMessage
	__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
	; __NetWebView2_LastMessage_KEEPER($oWebV2M, $NETWEBVIEW2_MESSAGE__FRAME_WEB_MESSAGE_RECEIVED)
	$oFrame = 0
EndFunc   ;==>__NetWebView2_Events__OnFrameWebMessageReceived

Func __NetWebView2_Events__FrameKeeper($oWebV2M, $hGUI, $oFrame)
	#TODO mLipok
	#forceref $oWebV2M, $hGUI, $oFrame
;~ 	Local Static $aFrames[0][2]
;~ 	Local Const $aFrameTemplate
;~
EndFunc   ;==>__NetWebView2_Events__FrameKeeper
#EndRegion ; === NetWebView2Lib UDF === EVENT HANDLERS === Frame Related ===

#Region ; === NetWebView2Lib UDF === EVENT HANDLERS * #TODO ===
;~ is this followed webmessagereceived are the same as __NetWebView2_Events__OnMessageReceived() ?
;~ https://learn.microsoft.com/en-us/microsoft-edge/webview2/reference/winrt/microsoft_web_webview2_core/corewebview2frame?view=webview2-winrt-1.0.3595.46#webmessagereceived

;~ Volatile Func __NetWebView2_Events__OnScreenCaptureStarting()
;~ https://learn.microsoft.com/en-us/microsoft-edge/webview2/reference/winrt/microsoft_web_webview2_core/corewebview2frame?view=webview2-winrt-1.0.3595.46#screencapturestarting
;~ EndFunc   ;==>__NetWebView2_Events__OnScreenCaptureStarting
#EndRegion ; === NetWebView2Lib UDF === EVENT HANDLERS * #TODO ===

#EndRegion ; === NetWebView2Lib UDF === EVENT HANDLERS ***** Collection *****