modules/output: produce empty files by default

Author: stasjok

modules/output.nix

@@ -99,24 +99,32 @@ in
 
   config =
     let
+      hasContent = str: (builtins.match "[[:space:]]*" str) == null;
+
       contentLua = ''
         ${config.extraConfigLuaPre}
-        vim.cmd([[
-          ${config.extraConfigVim}
-        ]])
+        ${lib.optionalString (hasContent config.extraConfigVim) ''
+          vim.cmd([[
+            ${config.extraConfigVim}
+          ]])
+        ''}
         ${config.extraConfigLua}
         ${config.extraConfigLuaPost}
       '';
 
       contentVim = ''
-        lua << EOF
-          ${config.extraConfigLuaPre}
-        EOF
+        ${lib.optionalString (hasContent config.extraConfigLuaPre) ''
+          lua << EOF
+            ${config.extraConfigLuaPre}
+          EOF
+        ''}
         ${config.extraConfigVim}
-        lua << EOF
-          ${config.extraConfigLua}
-          ${config.extraConfigLuaPost}
-        EOF
+        ${lib.optionalString (hasContent config.extraConfigLua || hasContent config.extraConfigLuaPost) ''
+          lua << EOF
+            ${config.extraConfigLua}
+            ${config.extraConfigLuaPost}
+          EOF
+        ''}
       '';
     in
     {

tests/test-sources/modules/output.nix

@@ -4,4 +4,59 @@
     # Make sure jsregexp is in LUA_PATH
     extraConfigLua = ''require("jsregexp")'';
   };
+
+  # Test that all extraConfigs are present in output
+  all-configs.module =
+    { config, ... }:
+    let
+      configs = {
+        extraConfigLuaPre = "string.format('extraConfigLuaPre')";
+        extraConfigLua = "string.format('extraConfigLua')";
+        extraConfigLuaPost = "string.format('extraConfigLuaPost')";
+        extraConfigVim = "let g:var = 'extraConfigVim'";
+      };
+      configAssertion = name: config: {
+        assertion =
+          builtins.match ".*extraConfigLuaPre.*" config != null
+          && builtins.match ".*extraConfigLua.*" config != null
+          && builtins.match ".*extraConfigLuaPost.*" config != null
+          && builtins.match ".*extraConfigVim.*" config != null;
+        message = "Configuration file ${name} does not contain all extraConfigs.";
+      };
+    in
+    configs
+    // {
+      files = {
+        "test.lua" = configs;
+        "test.vim" = configs;
+      };
+
+      assertions = [
+        (configAssertion "init.lua" config.content)
+        (configAssertion "test.lua" config.files."test.lua".content)
+        (configAssertion "test.vim" config.files."test.vim".content)
+      ];
+    };
+
+  files-default-empty.module =
+    { config, ... }:
+    {
+      files = {
+        # lua type
+        "test.lua" = { };
+        # vim type
+        "test.vim" = { };
+      };
+
+      assertions = [
+        {
+          assertion = builtins.match "[[:space:]]*" config.files."test.lua".content != null;
+          message = "Default content of test.lua file is expected to be empty.";
+        }
+        {
+          assertion = builtins.match "[[:space:]]*" config.files."test.vim".content != null;
+          message = "Default content of test.vim file is expected to be empty.";
+        }
+      ];
+    };
 }