t3code-flake/flake.nix at main · omarcresp/t3code-flake · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
{
  description = "T3 Code desktop app flake for Linux and macOS";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs =
    { self, nixpkgs }:
    let
      lib = nixpkgs.lib;
      pname = "t3-code";
      version = "0.0.13";

      sources = {
        x86_64-linux = {
          url = "https://github.com/pingdotgg/t3code/releases/download/v0.0.13/T3-Code-0.0.13-x86_64.AppImage";
          hash = "sha256-oHKIh+aHsbGVHEoLLjItl6AbVRwvWVlZaIWyHKiekVc=";
        };
        x86_64-darwin = {
          url = "https://github.com/pingdotgg/t3code/releases/download/v0.0.13/T3-Code-0.0.13-x64.zip";
          hash = "sha256-U3btRSqzX9HIwBl4+x554zAjZGL18F6nvFwpfWKkG3w=";
        };
        aarch64-darwin = {
          url = "https://github.com/pingdotgg/t3code/releases/download/v0.0.13/T3-Code-0.0.13-arm64.zip";
          hash = "sha256-OuAlsTbi9GObDBiggPLwiU0FKWQUVXLxBVfc/IHqiwo=";
        };
      };

      supportedSystems = builtins.attrNames sources;

      mkMeta = system: {
        description = "T3 Code desktop app packaged from upstream release binaries";
        homepage = "https://github.com/pingdotgg/t3code";
        license = lib.licenses.mit;
        mainProgram = "t3-code";
        platforms = [ system ];
        sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
      };

      mkLinuxPackage =
        pkgs:
        let
          system = pkgs.stdenv.hostPlatform.system;
          src = pkgs.fetchurl sources.${system};
          appimageContents = pkgs.appimageTools.extractType2 {
            inherit pname version src;
          };
        in
        pkgs.appimageTools.wrapType2 {
          inherit pname version src;

          extraPkgs = _pkgs: [ ];

          extraInstallCommands = ''
            install -Dm444 ${appimageContents}/t3-code-desktop.desktop \
              $out/share/applications/t3-code.desktop
            install -Dm444 ${appimageContents}/usr/share/icons/hicolor/1024x1024/apps/t3-code-desktop.png \
              $out/share/pixmaps/t3-code.png
            install -Dm444 ${appimageContents}/usr/share/icons/hicolor/1024x1024/apps/t3-code-desktop.png \
              $out/share/icons/hicolor/1024x1024/apps/t3-code.png

            substituteInPlace $out/share/applications/t3-code.desktop \
              --replace-fail 'Exec=AppRun --no-sandbox %U' 'Exec=t3-code %U' \
              --replace-fail 'Icon=t3-code-desktop' "Icon=$out/share/pixmaps/t3-code.png"
          '';

          meta = mkMeta system;
        };

      mkDarwinPackage =
        pkgs:
        let
          system = pkgs.stdenv.hostPlatform.system;
          src = pkgs.fetchurl sources.${system};
          appName = "T3 Code (Alpha).app";
          executable = "T3 Code (Alpha)";
        in
        pkgs.stdenvNoCC.mkDerivation {
          inherit pname version src;

          nativeBuildInputs = [
            pkgs.makeBinaryWrapper
            pkgs.unzip
          ];

          dontFixup = true;

          unpackPhase = ''
            runHook preUnpack
            unzip -q "$src"
            runHook postUnpack
          '';

          installPhase = ''
            runHook preInstall

            mkdir -p "$out/Applications" "$out/bin"
            cp -R "${appName}" "$out/Applications/"

            makeWrapper \
              "$out/Applications/${appName}/Contents/MacOS/${executable}" \
              "$out/bin/t3-code"

            runHook postInstall
          '';

          meta = mkMeta system;
        };

      mkPackage =
        system:
        let
          pkgs = import nixpkgs { inherit system; };
        in
        if pkgs.stdenv.hostPlatform.isLinux then
          mkLinuxPackage pkgs
        else if pkgs.stdenv.hostPlatform.isDarwin then
          mkDarwinPackage pkgs
        else
          throw "Unsupported system: ${system}";
    in
    {
      packages = lib.genAttrs supportedSystems (
        system:
        let
          package = mkPackage system;
        in
        {
          default = package;
          t3-code = package;
        }
      );

      apps = lib.genAttrs supportedSystems (
        system:
        let
          package = self.packages.${system}.t3-code;
        in
        {
          default = self.apps.${system}.t3-code;
          t3-code = {
            type = "app";
            program = "${package}/bin/t3-code";
          };
        }
      );
    };
}