Using wild in a nix dev shell for a rust project

[chrisheib]

Wanted to try this out and got it working quite nicely using the nix derivation from the nixpkgs PR:

let
  # 1. Import nixpkgs
  pkgs = import <nixpkgs> {
    overlays = [
      # 2. Pull in the rust-overlay
      (import (
        builtins.fetchTarball {
          url = "https://github.com/oxalica/rust-overlay/archive/master.tar.gz";
        }
      ))
    ];
  };

  # pin nixpkgs for wild
  wildPkgs = import (builtins.fetchTarball {
    url = "https://github.com/NixOS/nixpkgs/archive/fc1e503d0f3efeb9f25e4ab5860d52d1b1079b38.tar.gz";
  }) { };

  wild = wildPkgs.callPackage (builtins.fetchurl {
    url = "https://raw.githubusercontent.com/RossSmyth/nixpkgs/fc1e503d0f3efeb9f25e4ab5860d52d1b1079b38/pkgs/by-name/wi/wild/package.nix";
  }) { };

  # 3. Now rust-bin is available
  rust = pkgs.rust-bin.stable.latest.default;

  buildInputs =
    with pkgs;
    [
      autoAddDriverRunpath
      binutils
      libxkbcommon
      pkg-config
      rust
      mold
      clang
    ]
    ++ [ wild ];
in
pkgs.mkShell {
  inherit buildInputs;
  LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath buildInputs;
  RUSTFLAGS = "-C linker=clang -C link-arg=--ld-path=wild";
  shellHook = ''
    echo "Rust $(rustc --version)"
    unset TEMP TMP TEMPDIR TMPDIR
    export RUST_BACKTRACE=1
  '';
}